VBA (Excel) Инициализировать весь массив без циклов

Вы можете инициализировать массив, указав размеры. Например

Dim myArray(10) As Integer
Dim myArray(1 to 10) As Integer

Если вы работаете с массивами, и если это ваш первый раз, я бы рекомендовал посетить Chip Pearson WEBITE.

Что это инициализирует? Например, что, если я хочу инициализировать весь массив до 13?

Если вы хотите инициализировать массив из 13 элементов, вы можете сделать это двумя способами.

Dim myArray(12) As Integer
Dim myArray(1 to 13) As Integer

В первой нижней границе массива начнется с 0, чтобы вы могли хранить 13 элементов в массиве. Например

myArray(0) = 1
myArray(1) = 2
'
'
'
myArray(12) = 13

Во втором примере вы указали нижние границы как 1, поэтому ваш массив начинается с 1 и может снова хранить 13 значений

myArray(1) = 1
myArray(2) = 2
'
'
'
myArray(13) = 13

Если вы инициализируете массив с использованием любого из вышеперечисленных методов, значение каждого элемента в массиве равно 0. Чтобы проверить, что попробовать этот код.

Sub Sample()
    Dim myArray(12) As Integer
    Dim i As Integer

    For i = LBound(myArray) To UBound(myArray)
        Debug.Print myArray(i)
    Next i
End Sub

или

Sub Sample()
    Dim myArray(1 to 13) As Integer
    Dim i As Integer

    For i = LBound(myArray) To UBound(myArray)
        Debug.Print myArray(i)
    Next i
End Sub

ПОСЛЕДНИЕ ОТ КОММЕНТАРИЙ

Итак, в этом примере каждое значение будет равно 13. Поэтому, если бы у меня был массив Dim myArray (300) As Integer, все 300 элементов имели бы значение 13

Как я уже упоминал, AFAIK, нет прямого способа добиться того, чего вы хотите. Сказав, что это один из способов, который использует функцию рабочего листа Rept для создания повторяющейся строки из 13. Как только мы получим эту строку, мы можем использовать SPLIT, используя "," в качестве разделителя. Но обратите внимание, что это создает вариантный массив, но может использоваться в вычислениях.

Обратите также внимание, что в следующих примерах myArray будет фактически содержать 301 значение, из которых последний пуст - вам придется учитывать это, дополнительно инициализируя это значение или удаляя последние "," из sNum перед операцией SPLIT.

Sub Sample()
    Dim sNum As String
    Dim i As Integer
    Dim myArray

    '~~> Create a string with 13 three hundred times separated by comma
    '~~> 13,13,13,13...13,13 (300 times)
    sNum = WorksheetFunction.Rept("13,", 300)
    sNum = Left(sNum, Len(sNum) - 1)

    myArray = Split(sNum, ",")

    For i = LBound(myArray) To UBound(myArray)
        Debug.Print myArray(i)
    Next i
End Sub

Использование массива вариантов в вычислениях

Sub Sample()
    Dim sNum As String
    Dim i As Integer
    Dim myArray

    '~~> Create a string with 13 three hundred times separated by comma
    sNum = WorksheetFunction.Rept("13,", 300)
    sNum = Left(sNum, Len(sNum) - 1)

    myArray = Split(sNum, ",")

    For i = LBound(myArray) To UBound(myArray)
        Debug.Print Val(myArray(i)) + Val(myArray(i))
    Next i
End Sub

Я хочу инициализировать каждый отдельный элемент массива до некоторого начального значения. Поэтому, если у меня есть массив Dim myArray (300). Так как целое число из 300 целых чисел, например, все 300 элементов будут иметь одинаковое начальное значение (например, число 13).

Может ли кто-нибудь объяснить, как это сделать, без цикла? Я бы хотел сделать это в одном заявлении, если это возможно.

Что я выиграю?

Sub SuperTest()
   Dim myArray
   myArray = Application.Transpose([index(Row(1:300),)-index(Row(1:300),)+13])
End Sub

Эта функция работает с переменными для размера и начального значения, она объединяет ответы tbur и Filipe.

Function ArrayIniValue(iSize As Integer, iValue As Integer)
Dim sIndex As String
sIndex = "INDEX(Row(1:" & iSize & "),)"
ArrayIniValue = Evaluate("=Transpose(" & sIndex & "-" & sIndex & "+" & iValue & ")")
End Function

Вызывается следующим образом:

myArray = ArrayIniValue(350, 13)

Один метод, который может использоваться для назначения значений целым элементам массива, заключается в том, чтобы поместить данные на неиспользованный рабочий лист и затем прочитать значения из листа в массив. Например, я хочу присвоить значения 123 целым элементам массива 5x5. Вот однострочный код для реализации такой задачи:

ReDim MyArray(1 To 5, 1 To 5): Range("A1:E5") = 123: MyArray = Range("A1:E5")

Хотя он немного медленный, но он отлично работает. Вы также можете удалить объявление массива.

Range("A1:E5") = 123: MyArray = Range("A1:E5")

Фактически вы можете легко изменить значение некоторых элементов. Например, предположим, что вы хотите изменить значение элементов MyArray (1,1), MyArray (1,5), MyArray (3,3), MyArray (5,1) и MyArray (5,5) до 789, тогда код будет таким:

Range("A1:E5") = 123: Range("A1,E1,C3,A5,E5") = 789: MyArray = Range("A1:E5")

Необычный способ ответа @rdhs на функцию:

Function arrayZero(size As Integer)
  arrayZero = Evaluate("=IF(ISERROR(Transpose(A1:A" & size & ")), 0, 0)")
End Function

И используйте вот так:

myArray = arrayZero(15)

Для VBA вам нужно инициализировать две строки.

Sub TestArray()

Dim myArray
myArray = Array(1, 2, 4, 8)

End Sub