Возвращаем индекс элемента в массиве Excel VBA

Question

Возвращаем индекс элемента в массиве Excel VBA

40

У меня есть массив prLst, который представляет собой список целых чисел. Целые числа не сортируются, поскольку их позиция в массиве представляет собой конкретный столбец в электронной таблице. Я хочу знать, как найти конкретное целое число в массиве и вернуть его индекс.

Кажется, что нет никакого ресурса, показывающего мне, как без превращения массива в диапазон на листе. Это кажется немного сложным. Это просто невозможно с VBA?

H3lue 11 авг. 2011, в 18:13

Источник

Теги:

vba

excel

arrays

find

indexing

5 ответов

2

массив вариантов:

    Public Function GetIndex(ByRef iaList() As Variant, ByVal value As Variant) As Long

    Dim i As Long

     For i = LBound(iaList) To UBound(iaList)
      If value = iaList(i) Then
       GetIndex = i
       Exit For
      End If
     Next i

    End Function

- самая быстрая версия для целых чисел (как было проверено ниже)

    Public Function GetIndex(ByRef iaList() As Integer, ByVal value As Integer) As Integer
     Dim i As Integer

     For i = LBound(iaList) To UBound(iaList)
      If iaList(i) = value Then: GetIndex = i: Exit For:
     Next i

    End Function

' a snippet, replace myList and myValue to your varible names: (also have not tested)

фрагмент, позволяет проверить предположение, что передача по ссылке в качестве аргумента означает что-то. (ответ отрицательный), чтобы использовать его, замените myList и myValue на ваши имена переменных:

  Dim found As Integer, foundi As Integer ' put only once
  found = -1
  For foundi = LBound(myList) To UBound(myList):
   If myList(foundi) = myValue Then
    found = foundi: Exit For
   End If
  Next
  result = found

чтобы доказать, что я сделал некоторые ориентиры

вот результаты:

---------------------------
Milliseconds
---------------------------
result0: 5 ' just empty loop

result1: 2702  ' function variant array

result2: 1498  ' function integer array

result3: 2511 ' snippet variant array

result4: 1508 ' snippet integer array

result5: 58493 ' excel function Application.Match on variant array

result6: 136128 ' excel function Application.Match on integer array
---------------------------
OK   
---------------------------

модуль:

Public Declare Function GetTickCount Lib "kernel32.dll" () As Long
#If VBA7 Then
    Public Declare PtrSafe Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As LongPtr) 'For 64 Bit Systems
#Else
    Public Declare Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As Long) 'For 32 Bit Systems
#End If

    Public Function GetIndex1(ByRef iaList() As Variant, ByVal value As Variant) As Long

    Dim i As Long

     For i = LBound(iaList) To UBound(iaList)
      If value = iaList(i) Then
       GetIndex = i
       Exit For
      End If
     Next i

    End Function


'maybe a faster variant for integers

    Public Function GetIndex2(ByRef iaList() As Integer, ByVal value As Integer) As Integer
     Dim i As Integer

     For i = LBound(iaList) To UBound(iaList)
      If iaList(i) = value Then: GetIndex = i: Exit For:
     Next i

    End Function

' a snippet, replace myList and myValue to your varible names: (also have not tested)



    Public Sub test1()
     Dim i As Integer

     For i = LBound(iaList) To UBound(iaList)
      If iaList(i) = value Then: GetIndex = i: Exit For:
     Next i

    End Sub


Sub testTimer()

Dim myList(500) As Variant, myValue As Variant
Dim myList2(500) As Integer, myValue2 As Integer
Dim n

For n = 1 To 500
myList(n) = n
Next

For n = 1 To 500
myList2(n) = n
Next

myValue = 100
myValue2 = 100


Dim oPM
Set oPM = New PerformanceMonitor
Dim result0 As Long
Dim result1 As Long
Dim result2 As Long
Dim result3 As Long
Dim result4 As Long
Dim result5 As Long
Dim result6 As Long

Dim t As Long

Dim a As Long

a = 0
Dim i
't = GetTickCount
oPM.StartCounter
For i = 1 To 1000000

Next
result0 = oPM.TimeElapsed() '  GetTickCount - t

a = 0

't = GetTickCount
oPM.StartCounter
For i = 1 To 1000000
a = GetIndex1(myList, myValue)
Next
result1 = oPM.TimeElapsed()
'result1 = GetTickCount - t


a = 0

't = GetTickCount
oPM.StartCounter
For i = 1 To 1000000
a = GetIndex2(myList2, myValue2)
Next
result2 = oPM.TimeElapsed()
'result2 = GetTickCount - t



a = 0

't = GetTickCount

oPM.StartCounter
Dim found As Integer, foundi As Integer ' put only once
For i = 1 To 1000000
found = -1
For foundi = LBound(myList) To UBound(myList):
 If myList(foundi) = myValue Then
  found = foundi: Exit For
 End If
Next
a = found
Next
result3 = oPM.TimeElapsed()
'result3 = GetTickCount - t



a = 0

't = GetTickCount

oPM.StartCounter
For i = 1 To 1000000
found = -1
For foundi = LBound(myList2) To UBound(myList2):
 If myList2(foundi) = myValue2 Then
  found = foundi: Exit For
 End If
Next
a = found
Next
result4 = oPM.TimeElapsed()
'result4 = GetTickCount - t


a = 0

't = GetTickCount
oPM.StartCounter
For i = 1 To 1000000
a = pos = Application.Match(myValue, myList, False)
Next
result5 = oPM.TimeElapsed()
'result5 = GetTickCount - t



a = 0

't = GetTickCount
oPM.StartCounter
For i = 1 To 1000000
a = pos = Application.Match(myValue2, myList2, False)
Next
result6 = oPM.TimeElapsed()
'result6 = GetTickCount - t


MsgBox "result0: " & result0 & vbCrLf & "result1: " & result1 & vbCrLf & "result2: " & result2 & vbCrLf & "result3: " & result3 & vbCrLf & "result4: " & result4 & vbCrLf & "result5: " & result5 & vbCrLf & "result6: " & result6, , "Milliseconds"
End Sub

класс с именем PerformanceMonitor

Option Explicit

Private Type LARGE_INTEGER
    lowpart As Long
    highpart As Long
End Type

Private Declare Function QueryPerformanceCounter Lib "kernel32" (lpPerformanceCount As LARGE_INTEGER) As Long
Private Declare Function QueryPerformanceFrequency Lib "kernel32" (lpFrequency As LARGE_INTEGER) As Long

Private m_CounterStart As LARGE_INTEGER
Private m_CounterEnd As LARGE_INTEGER
Private m_crFrequency As Double

Private Const TWO_32 = 4294967296# ' = 256# * 256# * 256# * 256#

Private Function LI2Double(LI As LARGE_INTEGER) As Double
Dim Low As Double
    Low = LI.lowpart
    If Low < 0 Then
        Low = Low + TWO_32
    End If
    LI2Double = LI.highpart * TWO_32 + Low
End Function

Private Sub Class_Initialize()
Dim PerfFrequency As LARGE_INTEGER
    QueryPerformanceFrequency PerfFrequency
    m_crFrequency = LI2Double(PerfFrequency)
End Sub

Public Sub StartCounter()
    QueryPerformanceCounter m_CounterStart
End Sub

Property Get TimeElapsed() As Double
Dim crStart As Double
Dim crStop As Double
    QueryPerformanceCounter m_CounterEnd
    crStart = LI2Double(m_CounterStart)
    crStop = LI2Double(m_CounterEnd)
    TimeElapsed = 1000# * (crStop - crStart) / m_crFrequency
End Property

Shimon Doodkin 26 фев. 2013, в 07:57

0

Плохая производительность при использовании цикла ...
Holene 09 нояб. 2015, в 08:59
0

Я думаю, что плохая производительность связана с использованием варианта в качестве аргументов. из-за эффекта предварительной выборки. т.е. если вся память может быть прочитана вперед. как все переменные одинаковы и читаются в порядке, он работает хорошо. если он перемещается по позициям памяти, использование ссылок может работать медленнее. каждый раз, когда он переходит по ссылке, он снижает производительность на o (1). для многих ссылок это похоже на (o (1) + o (1) + o (1) + o (1)) * nloop.
Shimon Doodkin 09 нояб. 2015, в 20:43
0

вариант представляет собой формат инкапсуляции. ole-объекты, такие как bstr и safe array, обычно являются ссылками вне процесса в системной памяти. и распределяется динамически. в разных позициях в памяти. и безопасный массив легко может быть массивом ссылок. и варианты также могут быть ссылкой на ссылку. так что это должно быть медленно по определению. Я думаю, что функции Excel взломать систему и оптимизированы для этого типа проблемы и быть быстрее, как-то игнорировать несколько ссылок и проверок, когда это возможно
Shimon Doodkin 09 нояб. 2015, в 20:48
0

Я думаю, может быть, это будет работать быстрее, если он будет использовать несколько ссылок меньше. как если бы аргументы были бы просто типа, как целое число. и переменные не будут ссылками, как массив byref. но byval для того, чтобы они были локальной копией, а не ссылкой (измените тип аргумента с варианта на целое и byref на byval), также возможно, чтобы не использовать функцию вместо фрагмента в каждом месте
Shimon Doodkin 09 нояб. 2015, в 20:52
1

Я сделал тест Пеф. на самом деле производительность очень хорошая. потому что с помощью цикла, а не с помощью функции Excel. Предварительное тестирование также показывает, что для массива есть справочная стоимость доступа для каждой функции, а также для каждого варианта в цикле. Кроме того, похоже, что матч Excel делает некоторое копирование данных и, возможно, преобразование в Range. это дорого с точки зрения производительности
Shimon Doodkin 09 нояб. 2015, в 22:23
0

Мой голос за класс монитора производительности
nkatsar 01 июнь 2017, в 18:16

Показать ещё 4 комментария

1

Здесь другой способ:

Option Explicit

' Just a little test stub. 
Sub Tester()

    Dim pList(500) As Integer
    Dim i As Integer

    For i = 0 To UBound(pList)

        pList(i) = 500 - i

    Next i

    MsgBox "Value 18 is at array position " & FindInArray(pList, 18) & "."
    MsgBox "Value 217 is at array position " & FindInArray(pList, 217) & "."
    MsgBox "Value 1001 is at array position " & FindInArray(pList, 1001) & "."

End Sub

Function FindInArray(pList() As Integer, value As Integer)

    Dim i As Integer
    Dim FoundValueLocation As Integer

    FoundValueLocation = -1

    For i = 0 To UBound(pList)

        If pList(i) = value Then

            FoundValueLocation = i
            Exit For

        End If

    Next i

    FindInArray = FoundValueLocation

End Function

Paul McLain 11 авг. 2011, в 20:21

2

цикл, чтобы найти значение?
egidiocs 21 май 2014, в 23:04

0

Учет того, начинается ли массив с нуля или единицы. Кроме того, когда функция 0 или 1 возвращается функцией, убедитесь, что она не сбита с толку как True или False, возвращаемые функцией.

Function array_return_index(arr As Variant, val As Variant, Optional array_start_at_zero As Boolean = True) As Variant

Dim pos
pos = Application.Match(val, arr, False)

If Not IsError(pos) Then
    If array_start_at_zero = True Then
        pos = pos - 1
        'initializing array at 0
    End If
   array_return_index = pos
Else
   array_return_index = False
End If

End Function

Sub array_return_index_test()
Dim pos, arr, val

arr = Array(1, 2, 4, 5)
val = 1

'When array starts at zero
pos = array_return_index(arr, val)
If IsNumeric(pos) Then
MsgBox "Array starting at 0; Value found at : " & pos
Else
MsgBox "Not found"
End If

'When array starts at one
pos = array_return_index(arr, val, False)
If IsNumeric(pos) Then
MsgBox "Array starting at 1; Value found at : " & pos
Else
MsgBox "Not found"
End If



End Sub

luvlogic 06 окт. 2014, в 12:10

0

Это то, что вы ищете?

public function GetIndex(byref iaList() as integer, byval iInteger as integer) as integer

dim i as integer

 for i=lbound(ialist) to ubound(ialist)
  if iInteger=ialist(i) then
   GetIndex=i
   exit for
  end if
 next i

end function

Jon49 11 авг. 2011, в 20:52

Ещё вопросы

Плохая производительность при использовании цикла ...
Я думаю, что плохая производительность связана с использованием варианта в качестве аргументов. из-за эффекта предварительной выборки. т.е. если вся память может быть прочитана вперед. как все переменные одинаковы и читаются в порядке, он работает хорошо. если он перемещается по позициям памяти, использование ссылок может работать медленнее. каждый раз, когда он переходит по ссылке, он снижает производительность на o (1). для многих ссылок это похоже на (o (1) + o (1) + o (1) + o (1)) * nloop.
вариант представляет собой формат инкапсуляции. ole-объекты, такие как bstr и safe array, обычно являются ссылками вне процесса в системной памяти. и распределяется динамически. в разных позициях в памяти. и безопасный массив легко может быть массивом ссылок. и варианты также могут быть ссылкой на ссылку. так что это должно быть медленно по определению. Я думаю, что функции Excel взломать систему и оптимизированы для этого типа проблемы и быть быстрее, как-то игнорировать несколько ссылок и проверок, когда это возможно
Я думаю, может быть, это будет работать быстрее, если он будет использовать несколько ссылок меньше. как если бы аргументы были бы просто типа, как целое число. и переменные не будут ссылками, как массив byref. но byval для того, чтобы они были локальной копией, а не ссылкой (измените тип аргумента с варианта на целое и byref на byval), также возможно, чтобы не использовать функцию вместо фрагмента в каждом месте
Я сделал тест Пеф. на самом деле производительность очень хорошая. потому что с помощью цикла, а не с помощью функции Excel. Предварительное тестирование также показывает, что для массива есть справочная стоимость доступа для каждой функции, а также для каждого варианта в цикле. Кроме того, похоже, что матч Excel делает некоторое копирование данных и, возможно, преобразование в Range. это дорого с точки зрения производительности
Мой голос за класс монитора производительности

Tim Williams · Accepted Answer · 2011-08-11T20-00-00.000Z

Dim pos, arr, val

arr=Array(1,2,4,5)
val = 4

pos=Application.Match(val, arr, False)

if not iserror(pos) then
   Msgbox val & " is at position " & pos
else
   Msgbox val & " not found!"
end if

Обновлено, чтобы показать, используя Match (с .Index), чтобы найти значение в измерении двумерного массива:

Dim arr(1 To 10, 1 To 2)
Dim x

For x = 1 To 10
    arr(x, 1) = x
    arr(x, 2) = 11 - x
Next x

Debug.Print Application.Match(3, Application.Index(arr, 0, 1), 0)
Debug.Print Application.Match(3, Application.Index(arr, 0, 2), 0)

EDIT: стоит ли здесь упомянуть то, что @ARich указал в комментариях - использование Index() для среза массива имеет ужасную производительность, если вы делаете это в цикле.

При тестировании (код ниже) подход Index() почти в 2000 раз медленнее, чем использование вложенного цикла.

Sub PerfTest()

    Const VAL_TO_FIND As String = "R1800:C8"
    Dim a(1 To 2000, 1 To 10)
    Dim r As Long, c As Long, t

    For r = 1 To 2000
        For c = 1 To 10
            a(r, c) = "R" & r & ":C" & c
        Next c
    Next r

    t = Timer
    Debug.Print FindLoop(a, VAL_TO_FIND), Timer - t
    ' >> 0.00781 sec

     t = Timer
    Debug.Print FindIndex(a, VAL_TO_FIND), Timer - t
    ' >> 14.18 sec

End Sub

Function FindLoop(arr, val) As Boolean
    Dim r As Long, c As Long
    For r = 1 To UBound(arr, 1)
    For c = 1 To UBound(arr, 2)
        If arr(r, c) = val Then
            FindLoop = True
            Exit Function
        End If
    Next c
    Next r
End Function

Function FindIndex(arr, val)
    Dim r As Long
    For r = 1 To UBound(arr, 1)
        If Not IsError(Application.Match(val, Application.Index(arr, r, 0), 0)) Then
            FindIndex = True
            Exit Function
        End If
    Next r
End Function

и это работает! +1 Я действительно не знал, что можно использовать этот метод Match Match в массиве VBA!
Многие из функций листа Excel имеют аналогичную форму, доступную через Application.WorksheetFunction. [FunctionName] Обратите внимание, что если вы отбрасываете часть WorksheetFunction (как в моем примере), то возвращаемое значение функции можно затем проверить с помощью IsError (). Если вы включите часть WorksheetFunction, то (например), когда Match () не найдет совпадения, он выдаст ошибку, которую вам нужно будет отловить с помощью обработчика ошибок.
Ухоженная! Соответствие также работает на многомерных массивах?
Я использовал эту функцию для другой программы, которую я пишу, и по какой-то причине я получаю ошибку несоответствия типов, даже если первое значение является целым числом, а второе - массивом, содержащим целые числа. Есть ли причина, по которой это может произойти?
@ H3lue Трудно сказать, в чем ваша проблема без реального кода. Кроме того, вы даже не упоминаете, какую версию вы пытаетесь использовать ...
@TimWilliams Извините, что подружился с этим после столь долгого времени ... Я просто хотел указать будущим читателям, что в некоторых тестах, которые я проводил, возвращать ссылку "строка", как это делает метод Match/Index выше, это значительно быстрее использовать обычный цикл Do While (примерно на 530 процентов быстрее). Описанный выше метод все еще действительно полезен в определенных ситуациях, но если время имеет существенное значение, я рекомендую использовать цикл.
Следует также упомянуть, что я тестировал метод Match/Index на двумерном массиве; Я не тестировал пример Match на одномерном массиве, как показано выше.
Да, это не хак производительности. Я не думаю, что это быстрее на массиве 1d.
Есть ли способ использовать функцию Match с некоторой погрешностью? Я хотел бы использовать это для поиска индекса элемента в массиве с плавающей точкой.