Войти на сайт используя idhttp

Есть несколько проблем с вашим кодом:

1. вы не отправляете все, что находится в форме входа в систему. Вы должны это сделать. Это включает в себя значение самой кнопки входа, так как она имеет значения name и id. Для некоторых серверов это значение кнопки.

2. вы устанавливаете значение TIdHTTP.Request.ContentType недопустимым значением. Однако, случается, что TIdHTTP.Post(TIdMultipartFormDataStream) игнорирует предоставленный пользователем ContentType и использует TIdMultipartFormDataStream.RequestContentType свойство вместо этого. Таким образом, это не влияет на ваш логин, но он по-прежнему является ошибкой в вашем коде.

3. вы игнорируете кодировку ответов при загрузке данных ответа в TMemo. Вы должны использовать перегруженную версию TIdHTTP.Post() которая возвращает String и присваивает это TMemo.Text. Пусть TIdHTTP обрабатывает декодирование кодировки для вас.

4. вы протекаете объект TIdMultipartFormDataStream.

Попробуй это:

procedure TForm5.Login(name: string; Pass: string);
var
  MultiFormUpload: TIdMultiPartFormDataStream;
begin
  MultiFormUpload := TIdMultiPartFormDataStream.Create;
  try
    MultiFormUpload.AddFormField('user', name);
    MultiFormUpload.AddFormField('pass', pass);
    MultiFormUpload.AddFormField('sublogin', 'Login');

    //IdHTTP1.Get('http://codeelf.com');
    Memo1.Text := IdHTTP1.Post('http://codeelf.com/games/the-grid-2/grid', MultiFormUpload);
  finally
    MultiFormUpload.Free;
  end;
end;

При этом некоторые серверы отправляют файлы cookie клиенту, когда он запрашивает страницу входа в систему, а затем эти куки должны быть отправлены обратно как часть процесса входа в систему. Если сама публикация в URL-адрес входа не работает, сначала попробуйте получить страницу входа в систему, а затем разместите учетные данные для входа и разрешите TIdHTTP обрабатывать файлы cookie для вас:

procedure TForm5.Login(name: string; Pass: string);
var
  MultiFormUpload: TIdMultiPartFormDataStream;
begin
  MultiFormUpload := TIdMultiPartFormDataStream.Create;
  try
    MultiFormUpload.AddFormField('user', name);
    MultiFormUpload.AddFormField('pass', pass);
    MultiFormUpload.AddFormField('sublogin', 'Login');

    IdHTTP1.Get('http://codeelf.com/games/the-grid-2/grid', TStream(nil));
    Memo1.Text := IdHTTP1.Post('http://codeelf.com/games/the-grid-2/grid', MultiFormUpload);
  finally
    MultiFormUpload.Free;
  end;
end;

Обновление: есть еще одна проблема с вашим исходным кодом. Форма входа в систему HTML не запрашивает сообщение с multipart/form-data, поэтому TIdMultipartFormDataStream является неправильным классом. Вместо этого используйте TStringList поэтому TIdHTTP.Post() отправит вместо TIdHTTP.Post() сообщение application/x-www-form-urlencoded:

procedure TForm5.Login(name: string; Pass: string);
var
  Params: TStringList;
begin
  Params := TStringList.Create;
  try
    Params.Add('user='+name);
    Params.Add('pass='+pass);
    Params.Add('sublogin=Login');

    //IdHTTP1.Get('http://codeelf.com');
    Memo1.Text := IdHTTP1.Post('http://codeelf.com/games/the-grid-2/grid', Params);
  finally
    Params.Free;
  end;
end;