Почему прототипы функций Perl 5 плохие?

Проблема в том, что прототипы функций Perl не делают то, что люди думают, что они делают. Их цель - позволить вам писать функции, которые будут обрабатываться как встроенные функции Perl.

Прежде всего, вызовы методов полностью игнорируют прототипы. Если вы программируете OO, не имеет значения, какой прототип ваших методов имеет. (Поэтому у них не должно быть прототипов.)

Во-вторых, прототипы строго не соблюдаются. Если вы вызываете подпрограмму с &function(...), прототип игнорируется. Таким образом, они не обеспечивают безопасность любого типа.

В-третьих, это пугающее действие на расстоянии. (Особенно прототип $, который вызывает вычисление соответствующего параметра в скалярном контексте вместо контекста списка по умолчанию.)

В частности, они затрудняют передачу параметров из массивов. Например:

my @array = qw(a b c);

foo(@array);
foo(@array[0..1]);
foo($array[0], $array[1], $array[2]);

sub foo ($;$$) { print "@_\n" }

foo(@array);
foo(@array[0..1]);
foo($array[0], $array[1], $array[2]);

печатает:

a b c
a b
a b c
3
b
a b c

вместе с 3 предупреждениями о main::foo() called too early to check prototype (если предупреждения включены). Проблема в том, что массив (или срез массива), оцененный в скалярном контексте, возвращает длину массива.

Если вам нужно написать функцию, которая действует как встроенная, используйте прототип. В противном случае не используйте прототипы.

Примечание. Perl 6 будет полностью обновлен и очень полезен для прототипов. Этот ответ относится только к Perl 5.

Я согласен с этими двумя плакатами. В общем случае следует избегать использования $. Прототипы полезны только при использовании аргументов блока (&), globs (*) или эталонных прототипов (\@, \$, \%, \*)

Некоторые люди, глядя на прототип подпрограммы Perl, думают, что это означает что-то, чего нет:

sub some_sub ($$) { ... }

В Perl это означает, что парсер ожидает два аргумента. Это Perl способ позволить вам создавать подпрограммы, которые ведут себя как встроенные, все из которых знают, чего ожидать от следующего кода. Вы можете прочитать про прототипы в perlsub

Без чтения документации люди догадываются, что прототипы ссылаются на проверку аргументов времени выполнения или что-то подобное, что они видели на других языках. Как и большинство вещей, которые люди догадываются о Perl, они оказываются ошибочными.

Однако, начиная с Perl v5.20, Perl имеет функцию, экспериментальную, когда я пишу это, что дает нечто большее, что ожидают пользователи и что. Perl подписи подпрограммы запускает подсчет аргументов времени, назначение переменной и значение по умолчанию:

use v5.20;
use feature qw(signatures);
no warnings qw(experimental::signatures);

animals( 'Buster', 'Nikki', 'Godzilla' );

sub animals ($cat, $dog, $lizard = 'Default reptile') { 
    say "The cat is $cat";
    say "The dog is $dog";
    say "The lizard is $lizard";
    }

Это функция, которую вы, вероятно, захотите, если вы рассматриваете прототипы.