Я использовал это решение для извлечения имен методов из неуправляемой библиотеки C++, решение использует функцию SymEnumerateSymbols64
но MSDN говорит здесь, что приложения должны использовать SymEnumSymbols
вместо этого, поэтому я нашел это другое решение, но когда я попытался адаптировать и перевести код С# в код VB.NET, свойство SYMBOL_INFO.Name
содержит только первую букву имени метода.
Где проблема и как я могу это исправить?
Я думаю, что проблема может заключаться в декларации внутри структуры:
<MarshalAs(UnmanagedType.ByValTStr, SizeConst:=1024I)>
Public Name As String
... Но если я удалю сортировку, приложение просто закрывается без какого-либо исключения.
Это полный код:
<DllImport("dbghelp.dll", SetLastError:=True, CharSet:=CharSet.Unicode)>
Public Shared Function SymInitialize(
ByVal hProcess As IntPtr,
ByVal UserSearchPath As String,
<MarshalAs(UnmanagedType.Bool)> ByVal fInvadeProcess As Boolean
) As <MarshalAs(UnmanagedType.Bool)> Boolean
End Function
<DllImport("dbghelp.dll", SetLastError:=True, CharSet:=CharSet.Unicode)>
Public Shared Function SymCleanup(
ByVal hProcess As IntPtr
) As <MarshalAs(UnmanagedType.Bool)> Boolean
End Function
<DllImport("dbghelp.dll", SetLastError:=True, CharSet:=CharSet.Unicode)>
Public Shared Function SymLoadModuleEx(
ByVal hProcess As IntPtr,
ByVal hFile As IntPtr,
ByVal ImageName As String,
ByVal ModuleName As String,
ByVal BaseOfDll As Long,
ByVal DllSize As Integer,
ByVal Data As IntPtr,
ByVal Flags As SymLoadModuleFlags
) As ULong
End Function
<DllImport("dbghelp.dll", SetLastError:=True, CharSet:=CharSet.Unicode)>
Public Shared Function SymEnumSymbols(
ByVal hProcess As IntPtr,
ByVal BaseOfDll As ULong,
ByVal Mask As String,
ByVal EnumSymbolsCallback As SymEnumSymbolsProc,
ByVal UserContext As IntPtr
) As Boolean ' As <MarshalAs(UnmanagedType.Bool)> Boolean
End Function
Public Delegate Function SymEnumSymbolsProc(
ByRef pSymInfo As SYMBOL_INFO,
ByVal SymbolSize As UInteger,
ByVal UserContext As IntPtr
) As Boolean
<StructLayout(LayoutKind.Sequential)>
Public Structure SYMBOL_INFO
Public SizeOfStruct As UInteger
Public TypeIndex As UInteger
Public Reserved1 As ULong
Public Reserved2 As ULong
Public Reserved3 As UInteger
Public Size As UInteger
Public ModBase As ULong
Public Flags As SymFlag
Public Value As ULong
Public Address As ULong
Public Register As UInteger
Public Scope As UInteger
Public Tag As SymTagEnum
Public NameLen As Integer
Public MaxNameLen As Integer
<MarshalAs(UnmanagedType.ByValTStr, SizeConst:=1024)>
Public Name As String
End Structure
<FlagsAttribute>
Public Enum SymFlag As UInteger
VALUEPRESENT = &H1
REGISTER = &H8
REGREL = &H10
FRAMEREL = &H20
PARAMETER = &H40
LOCAL = &H80
CONSTANT = &H100
EXPORT = &H200
FORWARDER = &H400
[FUNCTION] = &H800
VIRTUAL = &H1000
THUNK = &H2000
TLSREL = &H4000
End Enum
<FlagsAttribute>
Public Enum SymTagEnum As UInteger
Null
Exe
Compiland
CompilandDetails
CompilandEnv
[Function]
Block
Data
Annotation
Label
PublicSymbol
UDT
[Enum]
FunctionType
PointerType
ArrayType
BaseType
Typedef
BaseClass
[Friend]
FunctionArgType
FuncDebugStart
FuncDebugEnd
UsingNamespace
VTableShape
VTable
[Custom]
Thunk
CustomType
ManagedType
Dimension
End Enum
<Description("Enum used as 'Flags' parameter of 'SymLoadModuleEx' function")>
<FlagsAttribute()>
Public Enum SymLoadModuleFlags As Integer
Module_And_Symbols = &H0I
Only_Module = &H4I
Virtual = &H1I
End Enum
Public Shared Function EnumSyms(ByRef pSymInfo As SYMBOL_INFO,
ByVal SymbolSize As UInteger,
ByVal UserContext As IntPtr) As Boolean
' Debug.WriteLine(pSymInfo.Name)
Debug.WriteLine(pSymInfo.Address & " " & SymbolSize & " " & pSymInfo.Name)
Return True
End Function
И это реальный пример использования:
Private Sub Test() Handles MyBase.Shown
Dim hCurrentProcess As IntPtr = Process.GetCurrentProcess().Handle
Dim baseOfDll As ULong
Dim status As Boolean
' Initialize sym.
' Please read the remarks on MSDN for the hProcess
' parameter.
status = SymInitialize(hCurrentProcess, Nothing, False)
If status = False Then
MsgBox("Failed to initialize sym.")
Exit Sub
End If
' Load dll.
baseOfDll = SymLoadModuleEx(hCurrentProcess,
IntPtr.Zero,
"C:\Users\Administrador\Desktop\x64.dll",
Nothing,
0,
0,
IntPtr.Zero,
SymLoadModuleFlags.Module_And_Symbols)
If baseOfDll = 0 Then
MsgBox("Failed to load module.")
SymCleanup(hCurrentProcess)
Exit Sub
End If
' Enumerate symbols. For every symbol the
' callback method EnumSyms is called.
If Not SymEnumSymbols(hCurrentProcess,
baseOfDll,
"*",
AddressOf EnumSyms,
IntPtr.Zero
) Then
MsgBox("Failed to enum symbols.")
End If
' Cleanup.
SymCleanup(hCurrentProcess)
End Sub
Я вижу несколько проблем с вашим кодом.
SYMBOL_INFO
Должен быть определен как класс. Структура vb.net не такая же, как структура C++.
Public Reserved1 As ULong
Public Reserved2 As ULong
Public Reserved3 As UInteger
Там всего два зарезервированных слова, а не три.
ULONG64 Reserved[2];
SymEnumSymbolsProc
ByRef pSymInfo As SYMBOL_INFO
Должен быть указатель на структуру SYMBOL_INFO, переданную ByVal.
_In_ PSYMBOL_INFO pSymInfo,
Образец формы
Imports System.Runtime.InteropServices
Imports System.ComponentModel
Public Class Form1
Private Sub HandleLoad(sender As Object, e As EventArgs) Handles MyBase.Load
Dim [error] As Exception = Nothing
Dim initialized As Boolean = False
Dim hProcess As IntPtr = Nothing
Try
SymSetOptions(2 Or 4)
hProcess = Process.GetCurrentProcess().Handle
If (SymInitialize(hProcess, Nothing, True)) Then
initialized = True
Else
Throw New Win32Exception(Marshal.GetLastWin32Error())
End If
Dim baseOfDll As IntPtr = SymLoadModuleEx(hProcess, IntPtr.Zero, (Environment.SystemDirectory & "\gdi32.dll"), Nothing, 0, 0, IntPtr.Zero, &H0I)
If (baseOfDll = IntPtr.Zero) Then
Throw New Win32Exception(Marshal.GetLastWin32Error())
End If
If Not SymEnumSymbols(
hProcess,
baseOfDll,
"*",
Function(pSymInfo As IntPtr, SymbolSize As UInteger, UserContext As IntPtr)
Dim struct As New SYMBOL_INFO
struct.SizeOfStruct = Marshal.SizeOf(GetType(SYMBOL_INFO))
Marshal.PtrToStructure(pSymInfo, struct)
Debug.WriteLine(struct.Name)
Return True
End Function, IntPtr.Zero
) Then
Throw New Win32Exception(Marshal.GetLastWin32Error())
End If
Catch ex As Exception
Debug.WriteLine(ex.Message)
Finally
If (initialized) Then
SymCleanup(hProcess)
End If
End Try
End Sub
<DllImport("dbghelp.dll", SetLastError:=True, CharSet:=CharSet.Auto)>
Private Shared Function SymSetOptions(ByVal SymOptions As Integer) As Integer
End Function
<DllImport("dbghelp.dll", SetLastError:=True, CharSet:=CharSet.Auto)>
Private Shared Function SymInitialize(ByVal hProcess As IntPtr, ByVal UserSearchPath As String, <MarshalAs(UnmanagedType.Bool)> ByVal fInvadeProcess As Boolean) As <MarshalAs(UnmanagedType.Bool)> Boolean
End Function
<DllImport("dbghelp.dll", SetLastError:=True, CharSet:=CharSet.Auto)>
Private Shared Function SymCleanup(ByVal hProcess As IntPtr) As <MarshalAs(UnmanagedType.Bool)> Boolean
End Function
<DllImport("dbghelp.dll", SetLastError:=True, CharSet:=CharSet.Auto)>
Private Shared Function SymLoadModuleEx(ByVal hProcess As IntPtr, ByVal hFile As IntPtr, ByVal ImageName As String, ByVal ModuleName As String, ByVal BaseOfDll As Long, ByVal DllSize As Integer, ByVal Data As IntPtr, ByVal Flags As Integer) As ULong
End Function
<DllImport("dbghelp.dll", SetLastError:=True, CharSet:=CharSet.Auto)>
Private Shared Function SymEnumSymbols(ByVal hProcess As IntPtr, ByVal BaseOfDll As ULong, ByVal Mask As String, ByVal EnumSymbolsCallback As SymEnumSymbolsProc, ByVal UserContext As IntPtr) As Boolean ' As <MarshalAs(UnmanagedType.Bool)> Boolean
End Function
Private Delegate Function SymEnumSymbolsProc(pSymInfo As IntPtr, ByVal SymbolSize As UInteger, ByVal UserContext As IntPtr) As Boolean
<StructLayout(LayoutKind.Sequential, CharSet:=CharSet.Auto)>
Private Class SYMBOL_INFO
Public SizeOfStruct As UInteger
Public TypeIndex As UInteger
Public Reserved1 As ULong
Public Reserved2 As ULong
Public Index As UInteger
Public Size As UInteger
Public ModBase As ULong
Public Flags As UInteger
Public Value As ULong
Public Address As ULong
Public Register As UInteger
Public Scope As UInteger
Public Tag As UInteger
Public NameLen As UInteger
Public MaxNameLen As UInteger
<MarshalAs(UnmanagedType.ByValTStr, SizeConst:=1024)> Public Name As String
End Class
End Class
arr(n-1)
отличается от c ++arr(n)
, они начинаются с нуля.