Получить атрибуты и диапазон, используя библиотеку HTMLAgilityPack

Ваша ошибка здесь, чтобы попытаться получить доступ к атрибуту childnode из найденного вами.

Когда вы вызываете node.SelectSingleNode("//div[@class='release']") вы получаете верный div, но вызов .Attributes возвращает только атрибуты самого тега div, а не внутренние элементы HTML.

Можно получить запросы XPATH, которые выбирают подузел, например //div[@class='release']/a - см. Http://www.w3schools.com/xpath/xpath_syntax.asp для получения дополнительной информации о XPATH. Хотя примеры для XML, большинство принципов должны применяться к HTML-документу.

Другой подход - использовать дальнейшие вызовы XPATH для найденного узла. Я изменил ваш код, чтобы он работал с использованием этого подхода:

' Load the html document.
htmldoc.LoadHtml(IO.File.ReadAllText("C:\source.html"))

' Select the (10 items) nodes.
htmlnodes = htmldoc.DocumentNode.SelectNodes("//div[@class='item']")

' Loop through the nodes.
For Each node As HtmlAgilityPack.HtmlNode In htmlnodes

    Dim releaseNode = node.SelectSingleNode(".//div[@class='release']")
    'Assumes we find the node and it has a a-tag
    Title = releaseNode.SelectSingleNode(".//a").Attributes("title").Value
    URL = releaseNode.SelectSingleNode(".//a").Attributes("href").Value

    Dim thumbNode = node.SelectSingleNode(".//div[@class='thumb']")
    Cover = thumbNode.SelectSingleNode(".//img").Attributes("src").Value

    Dim releaseYearNode = node.SelectSingleNode(".//div[@class='release-year']")
    Year = CInt(releaseYearNode.SelectSingleNode(".//span").InnerText)

    Dim genreNode = node.SelectSingleNode(".//div[@class='genre']")
    Dim genreLinks = genreNode.SelectNodes(".//a")
    Genres = (From n In genreLinks Select n.InnerText).ToArray()

    Console.WriteLine("Title : {0}", Title)
    Console.WriteLine("Cover : {0}", Cover)
    Console.WriteLine("Year  : {0}", Year)
    Console.WriteLine("Genres: {0}", String.Join(",", Genres))
    Console.WriteLine("URL   : {0}", URL)

Next

Обратите внимание, что в этом коде мы предполагаем, что документ правильно сформирован и что каждый атрибут node/element/существует и является правильным. Возможно, вы захотите добавить к ней много ошибок, например, If someNode Is Nothing Then....

Изменение: я немного изменил код выше, чтобы гарантировать, что каждый.SelectSingleNode использует префикс ".//" - это гарантирует, что он работает, если есть несколько узлов "item", в противном случае он выбирает первое совпадение из документа, а не текущее узел.

Если вы хотите более короткое решение XPATH, здесь используется тот же код, который использует этот подход:

' Load the html document.
htmldoc.LoadHtml(IO.File.ReadAllText("C:\source.html"))

' Select the (10 items) nodes.
htmlnodes = htmldoc.DocumentNode.SelectNodes("//div[@class='item']")

' Loop through the nodes.
For Each node As HtmlAgilityPack.HtmlNode In htmlnodes

    Title = node.SelectSingleNode(".//div[@class='release']/h4/a[@title]").Attributes("title").Value
    URL = node.SelectSingleNode(".//div[@class='release']/h4/a[@href]").Attributes("href").Value

    Cover = node.SelectSingleNode(".//div[@class='thumb']/a/img[@src]").Attributes("src").Value

    Year = CInt(node.SelectSingleNode(".//div[@class='release-year']/span").InnerText)

    Dim genreLinks = node.SelectNodes(".//div[@class='genre']/a")
    Genres = (From n In genreLinks Select n.InnerText).ToArray()

    Console.WriteLine("Title : {0}", Title)
    Console.WriteLine("Cover : {0}", Cover)
    Console.WriteLine("Year  : {0}", Year)
    Console.WriteLine("Genres: {0}", String.Join(",", Genres))
    Console.WriteLine("URL   : {0}", URL)
    Console.WriteLine()

Next