Какой самый простой способ вызвать Http GET URL с помощью Delphi?

Вызов веб-службы RESTful с помощью Indy довольно прост.

Добавьте IdHTTP в свой раздел uses. Помните, что IdHTTP нуждается в префиксе "HTTP://" на ваших URL-адресах.

function GetURLAsString(const aURL: string): string;
var
  lHTTP: TIdHTTP;
begin
  lHTTP := TIdHTTP.Create;
  try
    Result := lHTTP.Get(aURL);
  finally
    lHTTP.Free;
  end;
end;

На самом деле код в принятом ответе не работал у меня. Поэтому я немного изменил его, так что он фактически возвращает String и изящно закрывает все после выполнения. Пример возвращает полученные данные как UTF8String, поэтому он будет хорошо работать для ASCII, а также для страниц UTF8.

uses WinInet;

function GetUrlContent(const Url: string): UTF8String;
var
  NetHandle: HINTERNET;
  UrlHandle: HINTERNET;
  Buffer: array[0..1023] of byte;
  BytesRead: dWord;
  StrBuffer: UTF8String;
begin
  Result := '';
  NetHandle := InternetOpen('Delphi 2009', INTERNET_OPEN_TYPE_PRECONFIG, nil, nil, 0);
  if Assigned(NetHandle) then
    try
      UrlHandle := InternetOpenUrl(NetHandle, PChar(Url), nil, 0, INTERNET_FLAG_RELOAD, 0);
      if Assigned(UrlHandle) then
        try
          repeat
            InternetReadFile(UrlHandle, @Buffer, SizeOf(Buffer), BytesRead);
            SetString(StrBuffer, PAnsiChar(@Buffer[0]), BytesRead);
            Result := Result + StrBuffer;
          until BytesRead = 0;
        finally
          InternetCloseHandle(UrlHandle);
        end
      else
        raise Exception.CreateFmt('Cannot open URL %s', [Url]);
    finally
      InternetCloseHandle(NetHandle);
    end
  else
    raise Exception.Create('Unable to initialize Wininet');
end;

Надеюсь, что это поможет кому-то вроде меня, который искал простой код, как получить содержимое страницы в Delphi. Cheers, Aldis:)

Если вы можете загрузить файл, вы можете использовать TDownloadURL из модуля ExtActns. Гораздо проще, чем напрямую использовать WinInet.

procedure TMainForm.DownloadFile(URL: string; Dest: string);
var
  dl: TDownloadURL;
begin
  dl := TDownloadURL.Create(self);
  try
    dl.URL := URL;
    dl.FileName := Dest;
    dl.ExecuteTarget(nil); //this downloads the file
  finally
    dl.Free;
  end;
end;

Также можно получать уведомления о ходе работы при использовании этого. Просто назначьте обработчик событий событию TDownloadURL OnDownloadProgress.

Использование HTTP API HTTP также может быть легким.

procedure TForm1.Button1Click(Sender: TObject);
var http: variant;
begin
 http:=createoleobject('WinHttp.WinHttpRequest.5.1');
 http.open('GET', 'http://lazarus.freepascal.org', false);
 http.send;
 showmessage(http.responsetext);
end;

• https://msdn.microsoft.com/ru-ru/library/windows/desktop/aa382925.aspx
• http://forum.lazarus.freepascal.org/index.php?topic=14609.0
• Сохраните файл, загруженный через WinHTTP на диск, используя Delphi XE
• Как использовать "WinHttp.WinHttpRequest.5.1" асинхронно?
• http://www.delphigroups.info/2/4/217167.html
• https://github.com/fabriciocolombo/delphi-rest-client-api/blob/master/src/HttpConnectionWinHttp.pas

В приведенном выше коде я подразумеваю, что COM уже был инициализирован для основного потока VCL. Сообщается, что это может быть не всегда применительно к упрощенным приложениям или приложениям LCL. Кроме того, это определенно не будет иметь дело с асинхронной (многопоточной) работой.

Ниже приведен фрагмент текущего реального кода. Примечание. Функциональность - это бонус. Это не требуется для работы. Поэтому, когда я делаю запросы, мне не нужны их результаты, этот результат игнорируется и сбрасывается.

procedure TfmHaspList.YieldBlinkHTTP(const LED: boolean; const Key_Hardware_ID: cardinal);
var URL: WideString;
begin
  URL := 'http://127.0.0.1:1947/action.html?blink' +
    IfThen( LED, 'on', 'off') + '=' + IntToStr(Key_Hardware_ID);

  TThread.CreateAnonymousThread(
    procedure
    var Request: OleVariant;
    begin
      // COM library initialization for the current thread
      CoInitialize(nil);
      try
        // create the WinHttpRequest object instance
        Request := CreateOleObject('WinHttp.WinHttpRequest.5.1');
        // open HTTP connection with GET method in synchronous mode
        Request.Open('GET', URL, False);
        // set the User-Agent header value
//        Request.SetRequestHeader('User-Agent', 'Mozilla/4.0 (compatible; MSIE 6.0; Windows NT 5.0');
        // sends the HTTP request to the server, the Send method does not return
        // until WinHTTP completely receives the response (synchronous mode)
        Request.Send;
//        // store the response into the field for synchronization
//        FResponseText := Request.ResponseText;
//        // execute the SynchronizeResult method within the main thread context
//        Synchronize(SynchronizeResult);
      finally
        // release the WinHttpRequest object instance
        Request := Unassigned;
        // uninitialize COM library with all resources
        CoUninitialize;
      end;
    end
  ).Start;
end;

В новых версиях Delphi лучше использовать элемент THTTPClient от System.Net.HttpClient, поскольку он является стандартным и кросс-платформенным. Простой пример:

function GetURL(const AURL: string): string;
var
  HttpClient: THttpClient;
  HttpResponse: IHttpResponse;
begin
  HttpClient := THTTPClient.Create;
  try
    HttpResponse := HttpClient.Get(AURL);
    Result := HttpResponse.ContentAsString();
  finally
    HttpClient.Free;
  end;
end;

Используйте функцию Synapse TCP/IP в модуле HTTPSEND (HTTPGetText, HTTPGetBinary). Он будет тянуть HTTP для вас и не требует каких-либо внешних DLL, кроме Winsock. Последняя версия SVN отлично работает в Delphi 2009. Это использует вызовы функций блокировки, поэтому нет никаких событий для программирования.

Обновление: блоки очень легкие и не основаны на компонентах. Последняя версия SVN отлично работает и в Delphi XE4.

Если ваше приложение только для Windows, я бы предложил использовать WinSock. Он достаточно прост, позволяет выполнять любой HTTP-запрос, может работать как синхронно, так и асинхронно (используя неблокирующий WSASend/WSARecv с обратными вызовами или добрый старый send/recv в выделенном потоке).