if( $element ~~ @list ){
   do_task
}

~~ является "оператором интеллектуального соответствия" и не только распознает членство в списке.

Список:: Util:: first

$foo = first { ($_ && $_ eq "value" } @list;    # first defined value in @list

Или для типов ручной прокатки:

my $is_in_list = 0;
foreach my $elem (@list) {
    if ($elem && $elem eq $value_to_find) {
        $is_in_list = 1;
        last;
    }
}
if ($is_in_list) {
   ...

Несколько другая версия МОЖЕТ быть несколько быстрее в очень длинном списке:

my $is_in_list = 0;
for (my $i = 0; i < scalar(@list); ++$i) {
    if ($list[i] && $list[i] eq $value_to_find) {
        $is_in_list = 1;
        last;
    }
}
if ($is_in_list) {
   ...

Если вы планируете делать это много раз, вы можете обменять пространство для времени поиска:

#!/usr/bin/perl

use strict; use warnings;

my @array = qw( one ten twenty one );
my %lookup = map { $_ => undef } @array;

for my $element ( qw( one two three ) ) {
    if ( exists $lookup{ $element }) {
        print "$element\n";
    }
}

предполагая, что количество элементов, появляющихся в @array, не важно, а содержимое @array - простые скаляры.

Список:: MoreUtils

В perl >= 5.10 оператор smart match, безусловно, самый простой способ, как уже говорили многие другие.

В старых версиях perl я бы предложил List:: MoreUtils:: any.

List::MoreUtils не является основным модулем (некоторые говорят, что он должен быть), но он очень популярен и включен в основные дистрибутивы perl.

Он имеет следующие преимущества:

• возвращает true/false (как это делает Python in), а не значение элемента, поскольку List::Util::first делает (что затрудняет тестирование, как указано выше);
• в отличие от grep, он останавливается на первом элементе, который проходит тест (также как и короткие замыкания оператора perl smart match);
• он работает с любой версией perl (ну, >= 5.00503).

Вот пример, который работает с любым поисковым (скалярным) значением, включая undef:

use List::MoreUtils qw(any);

my $value = 'test'; # or any other scalar
my @array = (1, 2, undef, 'test', 5, 6);

no warnings 'uninitialized';

if ( any { $_ eq $value } @array ) {
    print "$value present\n"
}

P.S.

(В производственном коде лучше сузить область no warnings 'uninitialized').

TIMTOWTDI

sub is (&@) {
  my $test = shift;
  $test->() and return 1 for @_;
  0
}

sub in (@) {@_}

if( is {$_ eq "a"} in qw(d c b a) ) {
  print "Welcome in perl!\n";
}

grep здесь полезен

if (grep { $_ eq $element } @list) {
    ....
}

Вероятно, Perl6::Junction - самый ясный способ сделать. Никаких зависимостей XS, беспорядка и новой версии perl не требуется.

use Perl6::Junction qw/ any /;

if (any(@grant) eq 'su') {
    ...
}

Вы можете выполнить аналогичный синтаксис в Perl, если вы выполните Autoload взлом.

Создайте небольшой пакет для обработки автозагрузки:

package Autoloader;
use strict;
use warnings;

our $AUTOLOAD;

sub AUTOLOAD {
    my $self     = shift;
    my ($method) = (split(/::/, $AUTOLOAD))[-1];

    die "Object does not contain method '$method'" if not ref $self->{$method} eq 'CODE';

    goto &{$self->{$method}};
}

1;

Тогда ваш другой пакет или основной script будет содержать подпрограмму, которая возвращает объект, который обрабатывается Autoload, когда его метод пытается вызвать.

sub element {
    my $elem = shift;

    my $sub = {
        in => sub {
            return if not $_[0];

            # you could also implement this as any of the other suggested grep/first/any solutions already posted.
            my %hash; @hash{@_} = ();
            return (exists $hash{$elem}) ? 1 : ();
        }
    };

    bless($sub, 'Autoloader');
}

Это дает вам возможность выглядеть так:

doTask if element('something')->in(@array);

Если вы реорганизовываете закрытие и его аргументы, вы можете переключить синтаксис другим способом, чтобы он выглядел так, что немного ближе к стилю autobox:

doTask if search(@array)->contains('something');

чтобы сделать это:

sub search {
    my @arr = @_;

    my $sub = {
        contains => sub {
            my $elem = shift or return;
            my %hash; @hash{@arr} = ();
            return (exists $hash{$elem}) ? 1 : ();
        }
    };

    bless($sub, 'Autoloader');
}

В этом сообщении в блоге обсуждаются лучшие ответы на этот вопрос.

В качестве краткого резюме, если вы можете установить модули CPAN, лучшие решения:

if any(@ingredients) eq 'flour';

или

if @ingredients->contains('flour');

Однако более обычная идиома:

if @any { $_ eq 'flour' } @ingredients

который я считаю менее понятным.

Но, пожалуйста, не используйте функцию first()! Он не отражает намерения вашего кода вообще. Не используйте оператор "Smart match": он сломан. И не используйте grep() или решение с хешем: они перебирают весь список. Хотя any() остановится, как только он найдет ваше значение.

Подробнее читайте в блоге.

PS: Я отвечаю за людей, у которых будет тот же вопрос в будущем.