Получить список переданных аргументов в пакетном скрипте Windows (.bat)

%* похоже, содержит все аргументы, переданные в script.

%1... %n и %* содержат аргументы, но может быть сложно получить к ним доступ, потому что контент будет интерпретироваться.
Поэтому невозможно обработать что-то подобное с помощью обычных операторов

myBatch.bat "&"^&

Каждая строка выходит из строя, так как cmd.exe пытается выполнить один из амперсандов (содержимое% 1 есть "&"&)

set var=%1
set "var=%1"
set var=%~1
set "var=%~1"

Но существует обходное решение с временным файлом

@echo off
SETLOCAL DisableDelayedExpansion

SETLOCAL
for %%a in (1) do (
    set "prompt=$_"
    echo on
    for %%b in (1) do rem * #%1#
    @echo off
) > param.txt
ENDLOCAL

for /F "delims=" %%L in (param.txt) do (
  set "param1=%%L"
)
SETLOCAL EnableDelayedExpansion
set "param1=!param1:*#=!"
set "param1=!param1:~0,-2!"
echo %%1 is '!param1!'

Фокус в том, чтобы включить echo on и развернуть %1 после оператора rem (работает также с% 2..% *).
Но чтобы иметь возможность перенаправлять вывод echo on, вам нужны два FOR-LOOPS.

Дополнительные символы * # используются для защиты от содержимого, такого как /? (покажет помощь для REM).
Или каретка на конце строки может работать как многострочный символ.

FOR/F должен работать с отложенным расширением, иначе содержимое с помощью "!" будут уничтожены. После удаления дополнительных символов в param1 и вы получили его.

И чтобы безопасно использовать param1, включите отложенное расширение.

Изменить: одно примечание к% 0

%0 содержит команду, используемую для вызова пакета, также сохраняя случай, как в FoO.BaT
Но после вызова функции %0, а также в %~0 содержится имя функции (или лучше строка, которая использовалась для вызова функции).
Но с %~f0 вы все равно можете вспомнить имя файла.

@echo off
echo main %0, %~0, %~f0
call :myLabel+xyz
exit /b

:MYlabel
echo func %0, %~0, %~f0
exit /b

Выход

main test.bat, test.bat, C:\temp\test.bat
func :myLabel+xyz, :myLabel+xyz, C:\temp\test.bat

Я обнаружил, что в следующий раз, когда вам нужно найти эту информацию. Вместо того, чтобы открывать браузер и Google, вы можете просто ввести call /? в свой cmd, и вы получите его:

...

%* in a batch script refers to all the arguments (e.g. %1 %2 %3
    %4 %5 ...)

Substitution of batch parameters (%n) has been enhanced.  You can
now use the following optional syntax:

    %~1         - expands %1 removing any surrounding quotes (")
    %~f1        - expands %1 to a fully qualified path name
    %~d1        - expands %1 to a drive letter only
    %~p1        - expands %1 to a path only
    %~n1        - expands %1 to a file name only
    %~x1        - expands %1 to a file extension only
    %~s1        - expanded path contains short names only
    %~a1        - expands %1 to file attributes
    %~t1        - expands %1 to date/time of file
    %~z1        - expands %1 to size of file
    %~$PATH:1   - searches the directories listed in the PATH
                   environment variable and expands %1 to the fully
                   qualified name of the first one found.  If the
                   environment variable name is not defined or the
                   file is not found by the search, then this
                   modifier expands to the empty string

The modifiers can be combined to get compound results:

    %~dp1       - expands %1 to a drive letter and path only
    %~nx1       - expands %1 to a file name and extension only
    %~dp$PATH:1 - searches the directories listed in the PATH
                   environment variable for %1 and expands to the
                   drive letter and path of the first one found.
    %~ftza1     - expands %1 to a DIR like output line

In the above examples %1 and PATH can be replaced by other
valid values.  The %~ syntax is terminated by a valid argument
number.  The %~ modifiers may not be used with %*

Способ извлечения всех аргументов в script находится здесь:

@ECHO off
ECHO The %~nx0 script args are...
for %%I IN (%*) DO ECHO %%I
pause

Вот довольно простой способ получить аргументы и установить их как env vars. В этом примере я просто назову их как "Ключи и значения".

Сохраните следующий пример кода как "args.bat". Затем вызовите пакетный файл, который вы сохранили из командной строки. пример: arg.bat --x 90 --y 120

Я предоставил некоторые команды эха, чтобы перевести вас через процесс. Но конечным результатом является то, что --x будет иметь значение 90, а --y будет иметь значение 120 (то есть, если вы запустите пример, как указано выше ;-)).

Затем вы можете использовать условный оператор "if defined", чтобы определить, следует ли запускать ваш кодовый блок. Так что скажем, запустите: "arg.bat --x hello-world" Затем я мог бы использовать инструкцию "IF DEFINED --x echo% --x%", и результаты будут "hello-world". Это должно иметь смысл, если вы запускаете партию.

@setlocal enableextensions enabledelayedexpansion
@ECHO off
ECHO.
ECHO :::::::::::::::::::::::::: arg.bat example :::::::::::::::::::::::::::::::
ECHO :: By:      User2631477, 2013-07-29                                   ::
ECHO :: Version: 1.0                                                         ::
ECHO :: Purpose: Checks the args passed to the batch.                        ::
ECHO ::                                                                      ::
ECHO :: Start by gathering all the args with the %%* in a for loop.          ::
ECHO ::                                                                      ::
ECHO :: Now we use a 'for' loop to search for our keys which are identified  ::
ECHO :: by the text '--'. The function then sets the --arg ^= to the next    ::
ECHO :: arg. "CALL:Function_GetValue" ^<search for --^> ^<each arg^>         ::
ECHO ::                                                                      ::
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

ECHO.

ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO :: From the command line you could pass... arg.bat --x 90 --y 220       ::
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.
ECHO.Checking Args:"%*"

FOR %%a IN (%*) do (
    CALL:Function_GetValue "--","%%a" 
)

ECHO.
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO :: Now lets check which args were set to variables...                   ::
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO :: For this we are using the CALL:Function_Show_Defined "--x,--y,--z"   ::
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.
CALL:Function_Show_Defined "--x,--y,--z"
endlocal
goto done

:Function_GetValue

REM First we use find string to locate and search for the text.
echo.%~2 | findstr /C:"%~1" 1>nul

REM Next we check the errorlevel return to see if it contains a key or a value
REM and set the appropriate action.

if not errorlevel 1 (
  SET KEY=%~2
) ELSE (
  SET VALUE=%~2
)
IF DEFINED VALUE (
    SET %KEY%=%~2
    ECHO.
    ECHO ::::::::::::::::::::::::: %~0 ::::::::::::::::::::::::::::::
    ECHO :: The KEY:'%KEY%' is now set to the VALUE:'%VALUE%'                     ::
    ECHO :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
    ECHO.
    ECHO %KEY%=%~2
    ECHO.
    REM It important to clear the definitions for the key and value in order to
    REM search for the next key value set.
    SET KEY=
    SET VALUE=
)
GOTO:EOF

:Function_Show_Defined 
ECHO.
ECHO ::::::::::::::::::: %~0 ::::::::::::::::::::::::::::::::
ECHO :: Checks which args were defined i.e. %~2
ECHO :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.
SET ARGS=%~1
for %%s in (%ARGS%) DO (
    ECHO.
    ECHO :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
    ECHO :: For the ARG: '%%s'                         
    IF DEFINED %%s (
        ECHO :: Defined as: '%%s=!%%s!'                                             
    ) else (
        ECHO :: Not Defined '%%s' and thus has no value.
    )
    ECHO :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
    ECHO.
)
goto:EOF

:done

Следующий код имитирует массив ('params') - принимает параметры, полученные с помощью script, и сохраняет их в переменных params_1.. params_n, где n= params_0= количество элементов массива:

@echo off

rem Storing the program parameters into the array 'params':
rem Delayed expansion is left disabled in order not to interpret "!" in program parameters' values;
rem however, if a parameter is not quoted, special characters in it (like "^", "&", "|") get interpreted at program launch
set /a count=0
:repeat
    set /a count+=1
    set "params_%count%=%~1"
    shift
    if defined params_%count% (
        goto :repeat
    ) else (
        set /a count-=1
    )    
set /a params_0=count

rem Printing the program parameters stored in the array 'params':
rem After the variables params_1 .. params_n are set with the program parameters' values, delayed expansion can
rem be enabled and "!" are not interpreted in the variables params_1 .. params_n values
setlocal enabledelayedexpansion
    for /l %%i in (1,1,!params_0!) do (
        echo params_%%i: "!params_%%i!"
    )
endlocal

pause
goto :eof

Все, что я хотел сделать, это установить подсказку для текущего каталога, не зная, какая буква будет на флэш-накопителе, на котором он у меня был. Я пытался% C% и другие с странными результатами. Итак, я просто положил копию CMD.exe в ту же папку, из которой запускается командный файл, и это здорово.

Для использования циклов получить все аргументы и в чистом пакетном режиме:

@echo off && setlocal EnableDelayedExpansion

 set "_cnt=0" && for %%Z in (%*) do ( 
 set "_arg_=%%Z" && set /a "_cnt=!_cnt! + 1" && set "_arg_[!_cnt!]=!_arg_!"
 shift && for /l %%l in (!_cnt! 1 !_cnt!) do echo/ The argument n:%%l is: !_arg_[%%l]!
 )

goto :eof 

Ваш код готов сделать что-то с номером аргумента там, где это нужно, например...

 @echo off && setlocal EnableDelayedExpansion

 set "_cnt=0" && for %%Z in (%*) do ( 
 set "_arg_=%%Z" && set /a "_cnt=!_cnt! + 1" && set "_arg_[!_cnt!]=!_arg_!"
 shift 

 )

 run_command !_arg_[1]! !_arg_[2]! !_arg_[2]!> log.txt

Если у вас есть параметры в кавычках, содержащих пробелы, %* не будет работать правильно. Лучшее решение, которое я нашел, это иметь цикл, который объединяет все аргументы: https://serverfault.com/a/22541

set args=%1
shift
:start
if [%1] == [] goto done
set args=%args% %1
shift
goto start

:done
(use %args% here)

Большая часть приведенной выше информации привела меня к дальнейшим исследованиям и, в конечном счете, к моему ответу, поэтому я хотел внести свой вклад в то, что я сделал, надеясь, что это поможет кому-то другому:

• Я также хотел передать переменное количество переменных в пакетный файл, чтобы они могли обрабатываться в файле.

• Я был в порядке с передачей их в пакетный файл с использованием кавычек

• Я бы хотел, чтобы они обрабатывались аналогично приведенному ниже, но используя цикл вместо того, чтобы писать вручную:

Итак, я хотел выполнить это:

prog_ZipDeleteFiles.bat "_appPath=C:\Services\Logs\PCAP" "_appFile=PCAP*.?"

И через магию для циклов сделать это в пакетном файле:

set "_appPath=C:\Services\Logs\PCAP"
set "_appFile=PCAP*.?"

Проблема, с которой я столкнулась, заключается в том, что все мои попытки использовать цикл for не работали. Пример ниже:

for /f "tokens* delims= " in %%A (%*) DO (
   set %%A
)

просто:

set "_appPath=C:\Services\Logs\PCAP"

и не:

set "_appPath=C:\Services\Logs\PCAP"
set "_appFile=PCAP*.?"

даже после установки

SETLOCAL EnableDelayedExpansion

Причина заключалась в том, что цикл for считывал всю строку и назначал мой второй параметр %% B во время первой итерации цикла. Поскольку% * представляет все аргументы, обрабатывается только одна строка - ergo происходит только один проход цикла for. Это по дизайну получается, и моя логика была неправильной.

Итак, я перестал использовать цикл for и упростил то, что я пытался сделать, используя инструкции if, shift и goto. Согласился с этим немного взломать, но он больше подходит для моих нужд. Я могу пропустить все аргументы, а затем использовать оператор if, чтобы выходить из цикла, когда обрабатываю их все.

Вызывающее утверждение для того, что я пытался выполнить:

echo on
:processArguments
:: Process all arguments in the order received
if defined %1 then (
    set %1
    shift
    goto:processArguments
) ELSE (
    echo off 
)

UPDATE - мне пришлось изменить ниже, я подвергал все переменные окружения при попытке ссылаться на% 1 и использовал сдвиг таким образом:

echo on
shift
:processArguments
:: Process all arguments in the order received
if defined %0 then (
    set %0
    shift
    goto:processArguments
) ELSE (
    echo off 
)

@echo off
:start

:: Insert your code here
echo.%%1 is now:%~1
:: End insert your code here

if "%~2" NEQ "" (
    shift
    goto :start
)

Версия Windows (требуется, однако, socat)

C:\Program Files (x86)\Git\bin>type gitproxy.cmd
socat STDIO PROXY:proxy.mycompany.de:%1:%2,proxyport=3128

настройка:

C:\Users\exhau\AppData\Roaming\npm>git config --global core.gitproxy gitproxy.cmd

Вы можете использовать %1, %2 и т.д. для доступа к аргументам командной строки. Я не думаю, что есть переменная, содержащая весь список. Вы могли бы написать простой цикл, который определяет, сколько аргументов было передано.

EDIT: По-видимому, есть:)

Для тех, кому нужна обратная косая черта из basepath

set source=%~dp0
::Remove the trailing backslash from source
IF %source:~-1%==\ SET source=%source:~0,-1%
echo %source%