Правила регулярных выражений в Outlook 2007?

Я не знаю, может ли регулярное выражение использоваться непосредственно в правиле, но вы можете запустить триггер script, а script - использовать регулярные выражения. Я ненавижу Outlook.

Сначала вам нужно открыть редактор script с помощью инструмента "Инструменты" - "Макро" - "Открыть редактор Visual Basic" (Alt-F11 - это ярлык).

Откроется редактор. Он должен содержать схему проекта на небольшой панели в верхнем левом углу. Проект будет указан как VBAProject.OTM. Разверните этот элемент, чтобы открыть Microsoft Office Outlook Objects. Разверните это, чтобы открыть ThisOutlookSession. Дважды щелкните ThisOutlookSession, чтобы открыть панель редактирования кода (которая, вероятно, будет пустой).

Далее выберите меню "Сервис" | Ссылки и включите ссылки RegExp, называемые "Microsoft VBScript Regular Expressions 5.5"

Теперь вы можете создать подпрограмму для выполнения фильтрации. Обратите внимание, что подпрограмма, вызванная правилом, должна иметь единственный параметр типа Outlook.MailItem. Например:

' note that Qaru syntax highlighting doesn't understand VBScript's
' comment character (the single quote) - it treats it as a string delimiter.  To
' make the code appear correctly, each comment must be closed with another single
' quote so that the syntax highlighter will stop coloring everything as a string.'

Public Enum Actions
    ACT_DELIVER = 0
    ACT_DELETE = 1
    ACT_QUARANTINE = 2
End Enum

Sub MyNiftyFilter(Item As Outlook.MailItem)
    Dim Matches, Match
    Dim RegEx As New RegExp
    RegEx.IgnoreCase = True

    ' assume mail is good'
    Dim Message As String: Message = ""
    Dim Action As Actions: Action = ACT_DELIVER

    ' SPAM TEST: Illegal word in subject'
    RegEx.Pattern = "(v\|agra|erection|penis|boner|pharmacy|painkiller|vicodin|valium|adderol|sex med|pills|pilules|viagra|cialis|levitra|rolex|diploma)"
    If Action = ACT_DELIVER Then
        If RegEx.Test(Item.Subject) Then
            Action = ACT_QUARANTINE
            Set Matches = RegEx.Execute(Item.Subject)
            Message = "SPAM: Subject contains restricted word(s): " & JoinMatches(Matches, ",")
        End If
    End If

    ' other tests'

    Select Case Action
        Case Actions.ACT_QUARANTINE
            Dim ns As Outlook.NameSpace
            Set ns = Application.GetNamespace("MAPI")

            Dim junk As Outlook.Folder
            Set junk = ns.GetDefaultFolder(olFolderJunk)

            Item.Subject = "SPAM: " & Item.Subject
            If Item.BodyFormat = olFormatHTML Then
                Item.HTMLBody = "<h2>" & Message & "</h2>" & Item.HTMLBody
            Else
                Item.Body = Message & vbCrLf & vbCrLf & Item.Body
            End If

            Item.Save
            Item.Move junk

        Case Actions.ACT_DELETE
            ' similar to above, but grab Deleted Items folder as destination of move'

        Case Actions.ACT_DELIVER
            ' do nothing'
    End Select
End Sub


Private Function JoinMatches(Matches, Delimeter)
    Dim RVal: RVal = ""

    For Each Match In Matches
        If Len(RVal) <> 0 Then
            RVal = RVal & ", " & Match.Value
        Else
            RVal = RVal & Match.Value
        End If
    Next

    JoinMatches = RVal
End Function

Затем вы должны создать правило (Инструменты - Правила и предупреждения), чтобы вызвать этот script. Нажмите кнопку "Новое правило" в диалоговом окне, чтобы запустить мастер. Выберите шаблон для правила. Выберите шаблон "Проверить сообщения при их получении" в категории "Начать с пустого правила". Нажмите "Далее" .

Выберите условие "Только на этом компьютере" (интуитивно понятный, не так ли?) и нажмите "Далее" .

Выберите опцию "запустить a script". В нижней части мастера, где он показывает ваше новое правило, он должен читать:

Apply this rule after the message arrives
on this machine only
run a script

Фраза "a script" является кликабельной ссылкой. Щелкните по нему, и в Outlook появится диалоговое окно, в котором должна быть указана ранее созданная подпрограмма. Выберите свою подпрограмму и нажмите кнопку "ОК".

Вы можете нажать "Далее" , чтобы добавить исключения в правило или нажать "Готово", если у вас нет исключений.

Теперь, как если бы этот процесс не был достаточно сложным, это правило будет деактивироваться при каждом остановке и перезапуске Outlook, если вы не подпишете script с помощью ключа подписи кода.

Если у вас еще нет ключа подписи кода, вы можете создать один с OpenSSL.

Я упоминал, что ненавижу Outlook?