Правильная обработка ошибок в VBA (Excel)

У вас есть один поистине замечательный ответ от ray023, но ваш комментарий, что он, вероятно, слишком переполнен. Для "более светлой" версии....

Блок 1 есть, ИМХО, плохая практика. Как уже указывалось osknows, смешивание ошибок с кодом нормального пути не является хорошим. Во-первых, если новая ошибка возникает, когда возникает условие ошибки, вы можете не получить возможность обрабатывать ее (если вы не вызываете из процедуры, которая также имеет обработчик ошибок, где выполнение "пузырится" ).

Блок 2 выглядит как имитация блока Try/Catch. Это должно быть хорошо, но это не путь VBA. Блок 3 - это вариант на блоке 2.

Блок 4 - это голой версии VBA Way. Я бы настоятельно советовал использовать его или что-то в этом роде, потому что это будет ожидать любой другой программист VBA, наследующий код. Позвольте мне представить небольшое расширение, хотя:

Private Sub DoSomething()
On Error GoTo ErrHandler

'Dim as required

'functional code that might throw errors

ExitSub:
    'any always-execute (cleanup?) code goes here -- analagous to a Finally block.
    'don't forget to do this -- you don't want to fall into error handling when there no error
    Exit Sub

ErrHandler:
    'can Select Case on Err.Number if there are any you want to handle specially

    'display to user
    MsgBox "Something wrong: " & vbCrLf & Err.Description

    'or use a central DisplayErr routine, written Public in a Module
    DisplayErr Err.Number, Err.Description

    Resume ExitSub
    Resume
End Sub

Обратите внимание, что второй Resume. Это трюк, который я недавно узнал: он никогда не будет выполняться при нормальной обработке, так как оператор Resume <label> отправит выполнение в другом месте. Тем не менее, это может быть находкой для отладки. Когда вы получите уведомление об ошибке, выберите "Отладка" (или нажмите "Ctl-Break", затем выберите "Отладка", когда вы получите сообщение "Исполнение было прервано" ). Следующий (выделенный) оператор будет либо MsgBox, либо следующий оператор. Используйте "Установить следующее выражение" (Ctl-F9), чтобы выделить голый Resume, а затем нажмите F8. Это покажет вам, где именно была выбрана ошибка.

Что касается вашего возражения против этого формата, "прыгающего вокруг", A) это то, что ожидают программисты VBA, как указано ранее, и B) ваши подпрограммы должны быть достаточно короткими, чтобы он не мог прыгать.

Две основные цели для обработки ошибок:

• Ошибки ловушки вы можете предсказывать, но не может контролировать пользователя (например, сохранение файла на флэш-накопитель, когда флэш-накопители был удален)
• Для непредвиденных ошибок настоящий пользователь имеет форму что сообщает им, что проблема является. Таким образом, они могут сообщение вам, и вы, возможно, сможете дать им обход, пока вы работа над исправлением.

Итак, как бы вы это сделали?

Прежде всего, создайте форму ошибки для отображения при возникновении непредвиденной ошибки.

Он может выглядеть примерно так (FYI: Mine называется frmErrors):  

Обратите внимание на следующие метки:

• lblHeadline
• lblSource
• lblProblem
• lblResponse

Кроме того, стандартные кнопки команд:

• Игнорировать
• Retry
• Отмена

В коде для этой формы нет ничего эффектного:

Option Explicit

Private Sub cmdCancel_Click()
  Me.Tag = CMD_CANCEL
  Me.Hide
End Sub

Private Sub cmdIgnore_Click()
  Me.Tag = CMD_IGNORE
  Me.Hide
End Sub

Private Sub cmdRetry_Click()
  Me.Tag = CMD_RETRY
  Me.Hide
End Sub

Private Sub UserForm_Initialize()
  Me.lblErrorTitle.Caption = "Custom Error Title Caption String"
End Sub

Private Sub UserForm_QueryClose(Cancel As Integer, CloseMode As Integer)
  'Prevent user from closing with the Close box in the title bar.
    If CloseMode <> 1 Then
      cmdCancel_Click
    End If
End Sub

В принципе, вы хотите знать, какую кнопку пользователь нажал, когда форма закрывается.

Затем создайте модуль обработчика ошибок, который будет использоваться в вашем приложении VBA:

'****************************************************************
'    MODULE: ErrorHandler
'
'   PURPOSE: A VBA Error Handling routine to handle
'             any unexpected errors
'
'     Date:    Name:           Description:
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'03/22/2010    Ray      Initial Creation
'****************************************************************
Option Explicit

Global Const CMD_RETRY = 0
Global Const CMD_IGNORE = 1
Global Const CMD_CANCEL = 2
Global Const CMD_CONTINUE = 3

Type ErrorType
    iErrNum As Long
    sHeadline As String
    sProblemMsg As String
    sResponseMsg As String
    sErrorSource As String
    sErrorDescription As String
    iBtnCap(3) As Integer
    iBitmap As Integer
End Type

Global gEStruc As ErrorType
Sub EmptyErrStruc_S(utEStruc As ErrorType)
  Dim i As Integer

  utEStruc.iErrNum = 0
  utEStruc.sHeadline = ""
  utEStruc.sProblemMsg = ""
  utEStruc.sResponseMsg = ""
  utEStruc.sErrorSource = ""
  For i = 0 To 2
    utEStruc.iBtnCap(i) = -1
  Next
  utEStruc.iBitmap = 1

End Sub
Function FillErrorStruct_F(EStruc As ErrorType) As Boolean
  'Must save error text before starting new error handler
  'in case we need it later
  EStruc.sProblemMsg = Error(EStruc.iErrNum)
  On Error GoTo vbDefaultFill

  EStruc.sHeadline = "Error " & Format$(EStruc.iErrNum)
  EStruc.sProblemMsg = EStruc.sErrorDescription
  EStruc.sErrorSource = EStruc.sErrorSource
  EStruc.sResponseMsg = "Contact the Company and tell them you received Error # " & Str$(EStruc.iErrNum) & ". You should write down the program function you were using, the record you were working with, and what you were doing."

   Select Case EStruc.iErrNum
       'Case Error number here
       'not sure what numeric errors user will ecounter, but can be implemented here
       'e.g.
       'EStruc.sHeadline = "Error 3265"
       'EStruc.sResponseMsg = "Contact tech support. Tell them what you were doing in the program."

     Case Else

       EStruc.sHeadline = "Error " & Format$(EStruc.iErrNum) & ": " & EStruc.sErrorDescription
       EStruc.sProblemMsg = EStruc.sErrorDescription

   End Select

   GoTo FillStrucEnd

vbDefaultFill:

  'Error Not on file
  EStruc.sHeadline = "Error " & Format$(EStruc.iErrNum) & ": Contact Tech Support"
  EStruc.sResponseMsg = "Contact the Company and tell them you received Error # " & Str$(EStruc.iErrNum)
FillStrucEnd:

  Exit Function

End Function
Function iErrorHandler_F(utEStruc As ErrorType) As Integer
  Static sCaption(3) As String
  Dim i As Integer
  Dim iMCursor As Integer

  Beep

  'Setup static array
  If Len(sCaption(0)) < 1 Then
    sCaption(CMD_IGNORE) = "&Ignore"
    sCaption(CMD_RETRY) = "&Retry"
    sCaption(CMD_CANCEL) = "&Cancel"
    sCaption(CMD_CONTINUE) = "Continue"
  End If

  Load frmErrors

  'Did caller pass error info?  If not fill struc with the needed info
  If Len(utEStruc.sHeadline) < 1 Then
    i = FillErrorStruct_F(utEStruc)
  End If

  frmErrors!lblHeadline.Caption = utEStruc.sHeadline
  frmErrors!lblProblem.Caption = utEStruc.sProblemMsg
  frmErrors!lblSource.Caption = utEStruc.sErrorSource
  frmErrors!lblResponse.Caption = utEStruc.sResponseMsg

  frmErrors.Show
  iErrorHandler_F = frmErrors.Tag   ' Save user response
  Unload frmErrors                  ' Unload and release form

  EmptyErrStruc_S utEStruc          ' Release memory

End Function

У вас могут быть ошибки, которые будут доступны только для вашего приложения. Обычно это будет краткий список ошибок, особенно для вашего приложения. Если у вас еще нет модуля констант, создайте тот, который будет содержать ENUM ваших пользовательских ошибок. (ПРИМЕЧАНИЕ. Office '97 НЕ поддерживает ENUMS.). ENUM должен выглядеть примерно так:

Public Enum CustomErrorName
  MaskedFilterNotSupported
  InvalidMonthNumber
End Enum

Создайте модуль, который будет генерировать ваши пользовательские ошибки.

'********************************************************************************************************************************
'    MODULE: CustomErrorList
'
'   PURPOSE: For trapping custom errors applicable to this application
'
'INSTRUCTIONS:  To use this module to create your own custom error:
'               1.  Add the Name of the Error to the CustomErrorName Enum
'               2.  Add a Case Statement to the raiseCustomError Sub
'               3.  Call the raiseCustomError Sub in the routine you may see the custom error
'               4.  Make sure the routine you call the raiseCustomError has error handling in it
'
'
'     Date:    Name:           Description:
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'03/26/2010    Ray       Initial Creation
'********************************************************************************************************************************
Option Explicit
Const MICROSOFT_OFFSET = 512 'Microsoft reserves error values between vbObjectError and vbObjectError + 512
'************************************************************************************************
'  FUNCTION:  raiseCustomError
'
'   PURPOSE:  Raises a custom error based on the information passed
'
'PARAMETERS:  customError - An integer of type CustomErrorName Enum that defines the custom error
'             errorSource - The place the error came from
'
'   Returns:  The ASCII vaule that should be used for the Keypress
'
'     Date:    Name:           Description:
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'03/26/2010    Ray       Initial Creation
'************************************************************************************************
Public Sub raiseCustomError(customError As Integer, Optional errorSource As String = "")
  Dim errorLong As Long
  Dim errorDescription As String

  errorLong = vbObjectError + MICROSOFT_OFFSET + customError

  Select Case customError

    Case CustomErrorName.MaskedFilterNotSupported
      errorDescription = "The mask filter passed is not supported"

    Case CustomErrorName.InvalidMonthNumber
      errorDescription = "Invalid Month Number Passed"

    Case Else
      errorDescription = "The custom error raised is unknown."

  End Select

  Err.Raise errorLong, errorSource, errorDescription

End Sub

Теперь вы хорошо подготовлены для ловушек ошибок в вашей программе. Sub (или функция) должен выглядеть примерно так:

Public Sub MySub(monthNumber as Integer)
  On Error GoTo eh  

  Dim sheetWorkSheet As Worksheet

  'Run Some code here

  '************************************************
  '*   OPTIONAL BLOCK 1:  Look for a specific error
  '************************************************
  'Temporarily Turn off Error Handling so that you can check for specific error
  On Error Resume Next
  'Do some code where you might expect an error.  Example below:
  Const ERR_SHEET_NOT_FOUND = 9 'This error number is actually subscript out of range, but for this example means the worksheet was not found

  Set sheetWorkSheet = Sheets("January")

  'Now see if the expected error exists

  If Err.Number = ERR_SHEET_NOT_FOUND Then
    MsgBox "Hey!  The January worksheet is missing.  You need to recreate it."
    Exit Sub
  ElseIf Err.Number <> 0 Then
    'Uh oh...there was an error we did not expect so just run basic error handling 
    GoTo eh
  End If

  'Finished with predictable errors, turn basic error handling back on:
  On Error GoTo eh

  '**********************************************************************************
  '*   End of OPTIONAL BLOCK 1
  '**********************************************************************************

  '**********************************************************************************
  '*   OPTIONAL BLOCK 2:  Raise (a.k.a. "Throw") a Custom Error if applicable
  '**********************************************************************************
  If not (monthNumber >=1 and monthnumber <=12) then
    raiseCustomError CustomErrorName.InvalidMonthNumber, "My Sub"
  end if
  '**********************************************************************************
  '*   End of OPTIONAL BLOCK 2
  '**********************************************************************************

  'Rest of code in your sub

  goto sub_exit

eh:
  gEStruc.iErrNum = Err.Number
  gEStruc.sErrorDescription = Err.Description
  gEStruc.sErrorSource = Err.Source
  m_rc = iErrorHandler_F(gEStruc)

  If m_rc = CMD_RETRY Then
    Resume
  End If

sub_exit:
  'Any final processing you want to do.
  'Be careful with what you put here because if it errors out, the error rolls up.  This can be difficult to debug; especially if calling routine has no error handling.

  Exit Sub 'I was told a long time ago (10+ years) that exit sub was better than end sub...I can't tell you why, so you may not want to put in this line of code.  It habit I can't break :P
End Sub

Копия/вставка вышеприведенного кода может не работать прямо из ворот, но обязательно должна дать вам суть.

Кстати, если вам когда-нибудь понадобится сделать логотип вашей компании, найдите меня в http://www.MySuperCrappyLogoLabels99.com

Я делаю все просто:
На уровне модуля я определяю две переменные и устанавливаю ее на имя самого модуля.

    Private Const ThisModuleName            As String = "mod_Custom_Functions"
    Public sLocalErrorMsg                   As String

Внутри каждой Sub/Function модуля я определяю локальную переменную

    Dim ThisRoutineName                     As String

Я устанавливаю ThisRoutineName в имя суб или функции

' Housekeeping
    On Error Goto ERR_RTN
    ThisRoutineName = "CopyWorksheet"

Затем я отправляю все ошибки в ERR_RTN: когда они происходят, но я сначала установил sLocalErrorMsg, чтобы определить, что на самом деле является ошибкой, и предоставить некоторую информацию для отладки.

    If Len(Trim(FromWorksheetName)) < 1 Then
        sLocalErrorMsg = "Parameter 'FromWorksheetName' Is Missing."
        GoTo ERR_RTN
    End If

В нижней части каждой суб/функции я направляю логический поток следующим образом

    '
    ' The "normal" logic goes here for what the routine does
    '
    GoTo EXIT_RTN

    ERR_RTN:

        On Error Resume Next

    ' Call error handler if we went this far.
        ErrorHandler ThisModuleName, ThisRoutineName, sLocalErrorMsg, Err.Description, Err.Number, False

    EXIT_RTN:

        On Error Resume Next
     '
     ' Some closing logic
     '
    End If

Затем у меня есть отдельный модуль, который я помещал во все проекты под названием "mod_Error_Handler".

    '
    '''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
    ' Subroutine Name:     ErrorHandler                                                     '
    '                                                                                       '
    ' Description:                                                                          '
    '   This module will handle the common error alerts.                                    '
    '                                                                                       '
    ' Inputs:                                                                               '
    '   ModuleName                String    'The name of the module error is in.            '
    '   RoutineName               String    'The name of the routine error in in.           '
    '   LocalErrorMsg             String    'A local message to assist with troubleshooting.'
    '   ERRDescription            String    'The Windows Error Description.                 '
    '   ERRCode                   Long      'The Windows Error Code.                        '
    '   Terminate                 Boolean   'End program if error encountered?              '
    '                                                                                       '
    ' Revision History:                                                                     '
    ' Date (YYYYMMDD) Author                Change                                          '
    ' =============== ===================== =============================================== '
    ' 20140529        XXXXX X. XXXXX        Original                                        '
    '                                                                                       '
    '''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
    '
    Public Sub ErrorHandler(ModuleName As String, RoutineName As String, LocalErrorMsg As String, ERRDescription As String, ERRCode As Long, Terminate As Boolean)
        Dim sBuildErrorMsg                 As String

    ' Build Error Message To Display
        sBuildErrorMsg = "Error Information:" & vbCrLf & vbCrLf

        If Len(Trim(ModuleName)) < 1 Then
            ModuleName = "Unknown"
        End If

        If Len(Trim(RoutineName)) < 1 Then
           RoutineName = "Unknown"
        End If

        sBuildErrorMsg = sBuildErrorMsg & "Module Name:        " & ModuleName & vbCrLf & vbCrLf
        sBuildErrorMsg = sBuildErrorMsg & "Routine Name:       " & RoutineName & vbCrLf & vbCrLf

        If Len(Trim(LocalErrorMsg)) > 0 Then
            sBuildErrorMsg = sBuildErrorMsg & "Local Error Msg:    " & LocalErrorMsg & vbCrLf & vbCrLf
        End If

        If Len(Trim(ERRDescription)) > 0 Then
            sBuildErrorMsg = sBuildErrorMsg & "Program Error Msg:  " & ERRDescription & vbCrLf & vbCrLf
            If IsNumeric(ERRCode) Then
                sBuildErrorMsg = sBuildErrorMsg & "Program Error Code: " & Trim(Str(ERRCode)) & vbCrLf & vbCrLf
            End If
        End If

        MsgBox sBuildErrorMsg, vbOKOnly + vbExclamation, "Error Detected!"

        If Terminate Then
            End
        End If

    End Sub

Конечным результатом является всплывающее сообщение об ошибке, сообщающее мне, в каком модуле, что такое soubroutine и какое сообщение об ошибке было конкретно. Кроме того, он также введет сообщение об ошибке Windows и код.

Блок 2 не работает, потому что он не reset обработчик ошибок, потенциально вызывающий бесконечный цикл. Для правильной работы с ошибкой в ​​VBA вам понадобится инструкция Resume, чтобы очистить обработчик ошибок. Resume также активирует предыдущий обработчик ошибок. Блок 2 терпит неудачу, потому что новая ошибка вернется к предыдущему обработчику ошибок, вызывающему бесконечный цикл.

Ошибка блока 3, потому что нет инструкции Resume, поэтому любая попытка обработки ошибок после этого не будет выполнена.

Каждый обработчик ошибок должен быть завершен, выходя из процедуры или инструкции Resume. Обычное выполнение маршрутизации вокруг обработчика ошибок сбивает с толку. Вот почему обработчики ошибок обычно находятся внизу.

Но вот еще один способ справиться с ошибкой в ​​VBA. Он обрабатывает встроенный код ошибки, например Try/Catch в VB.net. Есть несколько подводных камней, но правильно управляемый он работает очень хорошо.

Sub InLineErrorHandling()

    'code without error handling

BeginTry1:

    'activate inline error handler
    On Error GoTo ErrHandler1

        'code block that may result in an error
        Dim a As String: a = "Abc"
        Dim c As Integer: c = a 'type mismatch

ErrHandler1:

    'handle the error
    If Err.Number <> 0 Then

        'the error handler has deactivated the previous error handler

        MsgBox (Err.Description)

        'Resume (or exit procedure) is the only way to get out of an error handling block
        'otherwise the following On Error statements will have no effect
        'CAUTION: it also reactivates the previous error handler
        Resume EndTry1
    End If

EndTry1:
    'CAUTION: since the Resume statement reactivates the previous error handler
    'you must ALWAYS use an On Error GoTo statement here
    'because another error here would cause an endless loop
    'use On Error GoTo 0 or On Error GoTo <Label>
    On Error GoTo 0

    'more code with or without error handling

End Sub

Источники:

• http://www.cpearson.com/excel/errorhandling.htm
• http://msdn.microsoft.com/en-us/library/bb258159.aspx

Ключом к выполнению этой работы является использование инструкции Resume, за которой следует другой оператор On Error. Resume находится внутри обработчика ошибок и переадресует код на метку EndTry1. Вы должны немедленно установить другой оператор On Error, чтобы избежать проблем, поскольку предыдущий обработчик ошибок "возобновится". То есть, он будет активным и готовым к обработке другой ошибки. Это может привести к тому, что ошибка повторится и введите бесконечный цикл.

Чтобы избежать повторного использования предыдущего обработчика ошибок, вам нужно установить On Error в новый обработчик ошибок или просто использовать On Error Goto 0 для отмены всей обработки ошибок.