Создайте TListView программно, не используя livebindings

Question

Создайте TListView программно, не используя livebindings

2

У меня есть кросс-платформенное приложение, которое содержит TFDMemtable (FireDAC).

Мой вопрос: как бы вручную создать TListView из записей в этой таблице?

В таблице у меня есть список кодовых имен для мужчин в алфавитном порядке.

например, Адам, Энтони, Алан, Брайан, Билл, Боб, Бен, Чарли, Крейг, Кристофер, Колин и так далее.

Я хочу, чтобы listview включал группы для имен, поэтому A, B, C и т.д.

У меня есть следующее:

procedure BuildNameList;
var Litem : TListViewItem;
c : Char;
begin
  ListView1.BeginUpdate;
  try
   ListView1.ClearItems;

  for c := 'A' to 'Z' do
  begin
    with ListView1.Items.Add do
    begin
      Text := char(c);
      Purpose := TListItemPurpose.Header;
    end;

  with dmod.tableNames do
  begin
    First;
   while not Eof do
    begin
      Litem := ListView1.Items.Add;         
      Litem.Text := dmod.tableNames.FieldByName('ForeName').AsString;
      Next;
    end;
  end;
  end;
  finally
    ListView1.EndUpdate;
end;

Вышеприведенный код не дает мне результата, который я получаю после, что происходит, я получаю каждое имя, дублируемое под каждой группой букв (AZ).

Любые предложения/помощь будут высоко оценены. благодаря

6String_Coder 31 март 2016, в 17:46

Источник

0

Пожалуйста, не используйте с
Peter-John Jansen 31 март 2016, в 16:25

Теги:

android

ios

delphi

firemonkey

delphi-xe8

1 ответ

Ещё вопросы

Ken White · Accepted Answer · 2016-03-31T15-13-00.000Z

Вам нужно немного изменить свою логику, чтобы добавить сначала заголовок, а затем имена под этим заголовком, а затем следующий заголовок и набор имен. Вот полное тестовое приложение, которое демонстрирует. Вам нужно будет удалить FMX TListView и TClientDataSet в своей форме и связать событие FormCreate, чтобы увидеть, как он работает. (Обратите внимание, что индекс необходим для ClientDataSet, чтобы гарантировать, что имена находятся в правильном порядке, если они не в алфавитном порядке, код не будет работать, потому что он не найдет данные по мере необходимости для добавления к раздел.)

unit Unit3;

interface

uses
  System.SysUtils, System.Types, System.UITypes, System.Classes, System.Variants,
  FMX.Types, FMX.Controls, FMX.Forms, FMX.Graphics, FMX.Dialogs, FMX.ListView.Types, Data.DB,
  Datasnap.DBClient, FMX.ListView;

type
  TForm3 = class(TForm)
    ListView1: TListView;
    CDS: TClientDataSet;
    procedure FormCreate(Sender: TObject);
  private
    { Private declarations }
    procedure BuildNameList;
  public
    { Public declarations }
  end;

var
  Form3: TForm3;

implementation

{$R *.fmx}

procedure TForm3.BuildNameList;
var
  Item: TListViewItem;
  Ch: Char;
begin
  ListView1.BeginUpdate;
  CDS.First;
  try
    ListView1.ClearItems;
    for Ch := 'A' to 'Z' do
    begin
      Item := ListView1.Items.Add;
      Item.Text := Ch;
      Item.Purpose := TListItemPurpose.Header;

      while (CDS.FieldByName('SurName').AsString[1] = Ch) and (not CDS.Eof) do
      begin
        Item := ListView1.Items.Add;
        Item.Text := CDS.FieldByName('SurName').AsString + ', ' +
                     CDS.FieldByName('ForeName').AsString;

        CDS.Next;
      end;
    end;
  finally
    ListView1.EndUpdate;
  end;
end;

procedure TForm3.FormCreate(Sender: TObject);
begin
  // Create some test data
  CDS.FieldDefs.Add('ForeName', ftString, 20);
  CDS.FieldDefs.Add('SurName', ftString, 30);
  CDS.CreateDataSet;
  CDS.Open;
  CDS.AppendRecord(['John', 'Smith']);
  CDS.AppendRecord(['Jane', 'Doe']);
  CDS.AppendRecord(['Ralph', 'Richards']);
  CDS.AppendRecord(['Fred', 'Fredericks']);
  CDS.AppendRecord(['Sam', 'Samuels']);
  CDS.AppendRecord(['Walter', 'Williams']);
  CDS.AppendRecord(['Ann', 'Anderson']);
  CDS.AppendRecord(['Bob', 'Barnes']);

  // Index it to put it in alphabetical order
  CDS.IndexDefs.Add('Names', 'SurName;ForeName', []);
  CDS.IndexName := 'Names';
  BuildNameList;
end;

end.

Вот скриншот центральной части этого примера ListView, так что вы можете увидеть результаты:

Спасибо за ваше предложение, но, к сожалению, оно не работает, оно только строит группы (A, B, C и т. Д.), А не поля имени в группах. Ваш код кажется намного более ясным по сравнению с тем, что я сделал, поэтому я посмотрю, куда еще я могу пойти отсюда и надеюсь достичь своей цели!
@ 6String_Coder: см. Мой обновленный пример кода. Это показывает, что работает правильно.
Я могу заставить его работать на Windows, но не на Android или iOS, список остается пустым.
Я не могу помочь тебе с этим; Я ответил на заданный вами вопрос о том, как правильно добавить элементы списка, и продемонстрировал, как это сделать. Вам придется использовать отладчик, чтобы выяснить, почему он не будет работать для вас в этих других ОС. (Вы знаете, что в документации есть пример, который показывает, как сделать это с ListBox вместо ListView который работает как на Android, так и на iOS?)
Это хорошо, вы были более чем полезны для меня. Я не был в восторге от этой документации, посмотрите сейчас. Большое спасибо еще раз.