Какой самый простой способ вызвать Http POST URL с помощью Delphi?

31

Вдохновленный вопросом Какой самый простой способ вызвать Http GET url с помощью Delphi? Я действительно хотел бы увидеть пример использования POST. Предпочтительно принимать XML от вызова.

Добавлено: как насчет включения изображения или другого файла в данные сообщения?

Теги:
http

3 ответа

41
Лучший ответ

Использование Indy. Поместите свои параметры в StringList (name = value) и просто вызовите Post с URL и StringList.

function PostExample: string;
var
  lHTTP: TIdHTTP;
  lParamList: TStringList;
begin
  lParamList := TStringList.Create;
  lParamList.Add('id=1');

  lHTTP := TIdHTTP.Create;
  try
    Result := lHTTP.Post('http://blahblahblah...', lParamList);
  finally
    lHTTP.Free;
    lParamList.Free;
  end;
end;
Поделиться
  • 0
    Поддержка TIdHTTP также https?
  • 1
    Да, TIdHTTP поддерживает HTTPS. stackoverflow.com/a/6693653/19183
Показать ещё 3 комментария
14

Вот пример использования Indy для публикации JPEG на веб-сервере с Gallery

У меня есть больше примеров такого рода вещей (я использую их в заставке, которую я написал в Delphi для проекта галереи, доступного здесь, или больше информации на веб-сайте галереи здесь).

Важный бит, я полагаю, состоит в том, что JPEG передается как поток.

procedure AddImage(const AlbumID: Integer; const Image: TStream; const ImageFilename, Caption, Description, Summary: String);
var
  Response: String;
  HTTPClient: TidHTTP;
  ImageStream: TIdMultipartFormDataStream;
begin

  HTTPClient := TidHTTP.Create;

  try
    ImageStream := TIdMultiPartFormDataStream.Create;
    try
      ImageStream.AddFormField('g2_form[cmd]', 'add-item');
      ImageStream.AddFormField('g2_form[set_albumId]', Format('%d', [AlbumID]));
      ImageStream.AddFormField('g2_form[caption]', Caption);
      ImageStream.AddFormField('g2_form[force_filename]', ImageFilename);
      ImageStream.AddFormField('g2_form[extrafield.Summary]', Summary);
      ImageStream.AddFormField('g2_form[extrafield.Description]', Description);

      ImageStream.AddObject('g2_userfile', 'image/jpeg', Image, ImageFilename);

      Response := HTTPClient.Post('http://mygallery.com/main.php?g2_controller=remote:GalleryRemote', ImageStream);
    finally
      ImageStream.Free;
    end;
  finally
    HTTPClient.Free;
  end;
end;
Поделиться
8

Опять же, Synapse TCP/IP library для спасения. Используйте процедуру HTTPSEND HTTPPostURL.

function HttpPostURL(const URL, URLData: string; const Data: TStream): Boolean;

Ваш URL-адрес будет также ресурсом для публикации, URLDATA будет представлять собой данные формы, и ваши результаты XML вернутся как поток в DATA.

Поделиться
  • 1
    Синапс, безусловно, еще один жизнеспособный вариант.

Ещё вопросы

Сообщество Overcoder
Наверх
Меню