ANTLR грамматический постфикс

Question

ANTLR грамматический постфикс

1

Я писал простую грамматику для небольшого языка, когда сталкивался с проблемой. Он бросает NullPointerException, когда я пытаюсь его интерпретировать. О, и это ANTLRWorks 3.

Кроме того, я указал, что язык должен быть Python, но он все еще делает вещи в Java:( Почему?

Здесь ввод:

program Test1 = 
const t1 : int := 1;
const t2 : int := 2;
var x, y, z : int;
begin
x := 41;
y := 10;
z := 2 4 *;
end Test1.

Здесь мой код:

grammar lang;

options {
    language=Python;
    output=AST;
    ASTLabelType=CommonTree;
}

tokens {DECL;} // an imaginary node

start : decl ;

decl : type ID ';' -> ^(DECL type ID)
     ;
type : INTTYPE  // automatic tree construction builds a node for this rule
     | FLOATTYPE
     ;
program
    : 'program' ID '='
    (const | variable)*
    'begin'
    statement*
    'end' ID '.'
    ;
const
    : 'const' ID ':' type ':=' expr ';'
    ;
variable
    : 'var' ID (',' ID)* ':' type ';'
    ;
statement
    : assignment
    ;
assignment
    : ID ':=' expr ';'
    ;



// expressions....fun!

term
    : ID
    | expr
    | INTTYPE
    ;
negation 
    : 'not'* term
    ;
unary
    : ('+' | '-')* negation
    ;
mult
    : unary (unary ('*' | '/' | 'mod'))*
    ;
add
    : mult (mult ('+' | '-'))*
    ;
relation
    : add (add ('==' | '!=' | '<' | '<=' | '>=' | '>'))*
    ;

expr
    : relation (relation ('and' | 'or'))* 
    ;

INTTYPE : 'int' ;
FLOATTYPE : 'float' ;
ID : ('a'..'z' | 'A'..'Z') ('a'..'z' | 'A'..'Z' | '0'..'9')* ;
INT : '0'..'9'+ ;
WS : (' '|'\n' | '\t') {$channel=HIDDEN;} ;

Что я делаю неправильно?

tekknolagi 14 июнь 2011, в 20:29

Источник

3

ANTLRWorks - это Java, независимо от того, какой language вы указываете в разделе options { ... } (ANTLRWorks игнорирует это!). Вы забыли упомянуть, на каком входе ваша грамматика выдает это исключение.
Bart Kiers 14 июнь 2011, в 17:48
0

упс ... добавлю что
tekknolagi 14 июнь 2011, в 17:59
0

добавлен! сделано :) спасибо за совет
tekknolagi 14 июнь 2011, в 18:01
1

Я попробовал вашу грамматику на ANTLRWorks 1.4.2 и получил это: i.stack.imgur.com/kzWeB.png
OscarRyz 14 июнь 2011, в 18:06
0

я смотрел этот урок vimeo.com/groups/29150/videos/8138418 и, похоже, он работал на этого парня ...
tekknolagi 14 июнь 2011, в 18:07
1

Не имеет отношения к вашему вопросу: ваша грамматика странная. Все операторы должны иметь одинаковый приоритет для правильного анализа общей постфиксной грамматики.
kay 14 июнь 2011, в 18:17
0

как бы я это сделал?
tekknolagi 14 июнь 2011, в 18:37
1

Нет, вы не делаете то же самое, что этот парень (кстати, его зовут Скотт ). Скотт сделал expr : relation (('and' | 'or') relation)*; в то время как вы сделали expr : relation (relation ('and' | 'or'))*; , Кроме того, вы использовали expr в своем term rule без каких-либо предварительных условий, что делало вашу грамматику рекурсивной , с чем ANTLR не может справиться.
Bart Kiers 14 июнь 2011, в 20:05
0

Вау! благодарю вас!
tekknolagi 14 июнь 2011, в 20:09

Показать ещё 7 комментариев

Теги:

python

antlr

1 ответ

Ещё вопросы

ANTLRWorks - это Java, независимо от того, какой language вы указываете в разделе options { ... } (ANTLRWorks игнорирует это!). Вы забыли упомянуть, на каком входе ваша грамматика выдает это исключение.
добавлен! сделано :) спасибо за совет
Я попробовал вашу грамматику на ANTLRWorks 1.4.2 и получил это: i.stack.imgur.com/kzWeB.png
я смотрел этот урок vimeo.com/groups/29150/videos/8138418 и, похоже, он работал на этого парня ...
Не имеет отношения к вашему вопросу: ваша грамматика странная. Все операторы должны иметь одинаковый приоритет для правильного анализа общей постфиксной грамматики.
Нет, вы не делаете то же самое, что этот парень (кстати, его зовут Скотт ). Скотт сделал expr : relation (('and' | 'or') relation)*; в то время как вы сделали expr : relation (relation ('and' | 'or'))*; , Кроме того, вы использовали expr в своем term rule без каких-либо предварительных условий, что делало вашу грамматику рекурсивной , с чем ANTLR не может справиться.

Bart Kiers · Accepted Answer · 2011-06-14T18-51-00.000Z

Как уже упоминал Кей: нет необходимости учитывать приоритет оператора в выражениях post- fix. post- fix выражения - это всего лишь список из одного или нескольких операндов и операторов. Здесь, как заставить вашу грамматику работать:

grammar lang;

options {
  language=Python;
  output=AST;
}

tokens {
  PROGRAM;
  STATS;
  DECL;
  ASSIGN;
  EXPR;
}

program
  :  'program' id=ID '=' decl* 'begin' statement* 'end' ID '.'
     -> ^(PROGRAM $id ^(DECL decl*) ^(STATS statement*))
  ;

decl
  :  const 
  |  variable
  ;

type 
  :  INTTYPE 
  |  FLOATTYPE
  ;

const
  :  'const' ID ':' type ':=' expr ';' -> ^('const' type ID expr)
  ;

variable
  :  'var' ID (',' ID)* ':' type ';' -> ^('var' type ID+)
  ;

statement
  :  assignment
  ;

assignment
  :  ID ':=' expr ';' -> ^(ASSIGN ID expr)
  ;

expr
  :  exprAtom+ -> ^(EXPR exprAtom+)
  ;

exprAtom
  :  operand 
  |  operator
  ;

operand
  :  INT
  |  ID
  ;

operator
  :  'and' | 'or' | '==' | '!=' | '<' | '<=' | '>=' | '>' | '+' | '-' | '*' | '/' | 'mod' | 'not'
  ;

INTTYPE   : 'int' ;
FLOATTYPE : 'float' ;
ID        : ('a'..'z' | 'A'..'Z') ('a'..'z' | 'A'..'Z' | '0'..'9')* ;
INT       : '0'..'9'+ ;
WS        : (' '|'\n' | '\t') {$channel=HIDDEN;} ;

Теперь создайте из него лексер и парсер (исходные файлы Python!), выполнив в командной строке следующее:

java -cp antlr-3.1.3.jar org.antlr.Tool lang.g

И если теперь вы выполните следующий script

#!/usr/bin/env python
import antlr3
from antlr3 import *
from antlr3.tree import *
from langLexer import *
from langParser import *

def print_level_order(tree, indent):
  print '{0}{1}'.format('   '*indent, tree.text)
  for child in tree.getChildren():
    print_level_order(child, indent+1)

input = """
program Test1 = 
const t1 : int := 1;
const t2 : int := 2;
var x, y, z : int;
begin
x := 41;
y := 10;
z := 2 4 *;
end Test1.
"""
char_stream = antlr3.ANTLRStringStream(input)
lexer = langLexer(char_stream)
tokens = antlr3.CommonTokenStream(lexer)
parser = langParser(tokens)
tree = parser.program().tree 
print_level_order(tree, 0)

вы увидите, что на консоль будет напечатано следующее:

PROGRAM
   Test1
   DECL
      const
         int
         t1
         EXPR
            1
      const
         int
         t2
         EXPR
            2
      var
         int
         x
         y
         z
   STATS
      ASSIGN
         x
         EXPR
            41
      ASSIGN
         y
         EXPR
            10
      ASSIGN
         z
         EXPR
            2
            4
            *