Как удалить файлы / подпапки в определенном каталоге в командной строке в Windows

rmdir - моя любимая команда во все времена для задания. Он работает для удаления огромных файлов и папок с подпапками. Резервная копия не создается, поэтому перед выполнением этой команды убедитесь, что вы скопировали файлы.

RMDIR "FOLDERNAME" /S /Q

Это тихо удаляет папку и все файлы и подпапки.

Самое простое решение, о котором я могу думать, - удалить весь каталог с помощью

RD /S /Q folderPath

Затем снова создайте этот каталог:

MD folderPath

Это позволит удалить папки и файлы и оставить папку позади.

pushd "%pathtofolder%" && (rd /s /q "%pathtofolder%" 2>nul & popd)

@ECHO OFF

Set dir=path-to-dir

Echo Deleting all files from %dir%
del %dir%\* /F /Q

Echo Deleting all folders from %dir%
for /d %%p in (%dir%\*) Do rd /Q /S "%%p"
@echo Folder deleted.


exit

... удаляет все файлы и папки под данным каталогом, но не сам каталог.

CD [Your_Folder]
RMDIR /S /Q .

Вы получите сообщение об ошибке, сообщите, что команда RMDIR не может получить доступ к текущей папке, поэтому она не может ее удалить.

Обновление:

Из этого полезного комментария (спасибо Moritz Both) вы можете добавить && между ними, поэтому RMDIR не будет работать, если команда CD завершится неудачно (например, неверное имя каталога):

CD [Your_Folder] && RMDIR /S /Q .

Из справочной системы Windows:

/S: Удаляет дерево каталогов (указанный каталог и все его подкаталоги, включая все файлы).

/Q: задает тихий режим. Не запрашивает подтверждение при удалении дерева каталогов. (Заметим, что /q работает, только если задано /s.)

RD означает REMOVE Directory.

/S: удаление всех файлов и подпапок        в дополнение к самой папке.        Используйте это, чтобы удалить все дерево папок.

/Q: Тихо - не отображать подтверждение YN

Пример:

RD /S /Q C:/folder_path/here

Я использую Powershell

Remove-Item c:\scripts\* -recurse

Он удалит содержимое папки, а не папку.

Используйте блокнот для создания текстового документа и скопируйте/вставьте его:

rmdir /s/q "%temp%"
mkdir "%temp%"

Выберите сохранение как, Имя файла:

delete_temp.bat

Сохранить как тип: Все файлы и нажмите кнопку "Сохранить".

Работайте с любым видом аккаунта (администратором или стандартным пользователем), просто запустите его! Я использую переменную temp в этом примере, но вы можете использовать любой другой! постскриптум Только для ОС Windows!

Вы можете выполнить следующую команду, чтобы удалить все содержимое и родительскую папку:

RMDIR [/S] [/Q] [drive:]path            

Ни один из ответов, отправленный в 2018-06-01, за исключением единственной командной строки, опубликованной foxidrive, действительно удалил все файлы и все папки/каталоги в %PathToFolder%. Это причина для отправки еще одного ответа с помощью простой простой командной строки для удаления всех файлов и подпапок папки, а также пакетного файла с более сложным решением, объясняющим, почему все остальные ответы, опубликованные в 2018-06-01, используя DEL и FOR с RD не удалось полностью очистить папку.

Простое решение одной командной строки, которое, конечно же, можно использовать и в пакетном файле:

pushd "%PathToFolder%" 2>nul && ( rd /Q /S "%PathToFolder%" 2>nul & popd )

Эта командная строка содержит три команды, выполняемые один за другим.

Первая команда PUSHD подталкивает текущий путь к каталогу в стеке, а затем делает %PathToFolder% текущим каталогом для запуска командного процесса.

Это работает также для UNC- путей по умолчанию из-за того, что расширения команд включены по умолчанию, и в этом случае PUSHD создает временную букву диска, которая указывает на указанный сетевой ресурс, а затем изменяет текущий диск и каталог, используя новую букву диска.

PUSHD выводит следующее сообщение об ошибке для обработки STDERR, если указанный каталог вообще не существует:

Система не может найти указанный путь.

Это сообщение об ошибке подавляется перенаправлением его с помощью 2>nul на устройство NUL.

Следующая команда RD выполняется только в том случае, если смена текущего каталога для текущего командного процесса в указанный каталог прошла успешно, т.е. Указанная директория существует вообще.

Команда RD с параметрами /Q и /S спокойно удаляет каталог со всеми подкаталогами, даже если указанный каталог содержит файлы или папки со скрытым атрибутом или с атрибутом только для чтения. Системный атрибут никогда не предотвращает удаление файла или папки.

Не удалены:

1. Папки, используемые в качестве текущего каталога для любого запущенного процесса. Полное дерево папок для такой папки не может быть удалено, если папка используется в качестве текущего каталога для любого запущенного процесса.

2. Файлы, открываемые в настоящий момент любым запущенным процессом с разрешениями доступа к файлам, установленными в файле, открываются для предотвращения удаления файла при открытии запущенного приложения/процесса. Такой открытый файл предотвращает также удаление всего дерева папок в открытый файл.

3. Файлы/папки, на которых у текущего пользователя нет необходимых (NTFS) разрешений для удаления файла/папки, который также предотвращает удаление дерева папок в этот файл/папку.

Первая причина не удалять папку используется этой командной строкой для удаления всех файлов и подпапок указанной папки, но не самой папки. Папка временно создается в текущем каталоге для запуска командного процесса, который предотвращает удаление самой папки. Конечно, это приводит к выходу сообщения об ошибке командой RD:

Процесс не может получить доступ к файлу, поскольку он используется другим процессом.

Файл здесь является неправильным термином, так как в реальной папке используется другой процесс, текущий командный процесс, который выполнял команду RD. Ну, в реальной папке для файловой системы есть специальный файл с файловым каталогом атрибутов, который объясняет это сообщение об ошибке. Но я не хочу углубляться в управление файловой системой.

Это сообщение об ошибке, как и все другие сообщения об ошибках, которые могут возникнуть из-за трех причин, описанных выше, подавляется перенаправлением его с помощью 2>nul от дескриптора STDERR к устройству NUL.

Третья команда POPD выполняется независимо от значения выхода команды RD.

POPD выдает путь к каталогу, выталкиваемый PUSHD из стека, и изменяет текущий каталог для запуска процесса обработки в этот каталог, то есть восстанавливает начальный текущий каталог. POPD удаляет временную букву диска, созданную PUSHD, в случае пути UNC-папки.

Примечание. POPD может без проблем восстановить исходный текущий каталог в случае, если исходный текущий каталог был подкаталогом каталога для очистки, который больше не существует. В этом специальном случае %PathToFolder% остается текущим каталогом. Поэтому рекомендуется запустить командную строку выше, а не из подкаталога %PathToFolder%.

Еще один интересный факт:
Я попробовал командную строку также с помощью UNC-пути, поделившись локальным каталогом C:\Temp с общим именем Temp и используя путь UNC \\%COMPUTERNAME%\Temp\CleanTest назначенный переменной окружения PathToFolder в Windows 7. Если текущий каталог запущен командная строка является подкаталог общей локальной папке доступ с помощью UNC - путь, т.е. C:\Temp\CleanTest\Subfolder1, Subfolder1 удаляется по РД, а следующий POPD терпит неудачу молча делает C:\Temp\CleanTest\Subfolder1 снова текущий каталог в результате Z:\CleanTest остается текущим каталогом для запуска команды. Таким образом, в этом очень, очень особенном случае временная буква диска остается до тех пор, пока текущий каталог не будет изменен, например, с помощью cd/D %SystemRoot% в существующий локальный каталог. К сожалению, POPD не выходит со значением больше 0, если ему не удается восстановить исходный текущий каталог, что делает невозможным обнаружение этого особого условия ошибки, используя только код выхода из POPD. Однако можно предположить, что никто не сталкивается с этим особым случаем ошибки, поскольку UNC-пути обычно не используются для доступа к локальным файлам и папкам.

Чтобы лучше понять используемые команды, откройте окно командной строки, выполните там следующие команды и внимательно прочитайте справку, отображаемую для каждой команды.

• pushd/?
• popd/?
• rd/?

Одиночная строка с несколькими командами с использованием командного файла Windows объясняет оператора && и & используется здесь.

Затем давайте посмотрим на решение пакетного файла, используя команду DEL для удаления файлов в %PathToFolder% и FOR и RD для удаления подпапок в %PathToFolder%.

@echo off
setlocal EnableExtensions DisableDelayedExpansion

rem Clean the folder for temporary files if environment variable
rem PathToFolder is not defined already outside this batch file.
if not defined PathToFolder set "PathToFolder=%TEMP%"

rem Remove all double quotes from folder path.
set "PathToFolder=%PathToFolder:"=%"

rem Consisted the folder path only of double quotes?
if not defined PathToFolder goto EndCleanFolder

rem Remove a backslash at end of folder path.
if "%PathToFolder:~-1%" == "\" set "PathToFolder=%PathToFolder:~0,-1%"

rem Consisted folder path only of a backslash (with one or more double quotes)?
if not defined PathToFolder goto EndCleanFolder

rem Delete all files in specified folder including files with hidden
rem or read-only attribute set, except the files currently opened by
rem a running process which prevents deletion of the file while being
rem opened by the application, or on which the current user has not
rem the required permissions to delete the file.
del /A /F /Q "%PathToFolder%\*" >nul 2>nul

rem Delete all subfolders in specified folder including those with hidden
rem attribute set recursive with all files and subfolders, except folders
rem being the current directory of any running process which prevents the
rem deletion of the folder and all folders above, folders containing a file
rem opened by the application which prevents deletion of the file and the
rem entire folder structure to this file, or on which the current user has
rem not the required permissions to delete a folder or file in folder tree
rem to delete.
for /F "eol=| delims=" %%I in ('dir "%PathToFolder%\*" /AD /B 2^>nul') do rd /Q /S "%PathToFolder%\%%I" 2>nul

:EndCleanFolder
endlocal

Пакетный файл сначала гарантирует, что переменная среды PathToFolder действительно определена с помощью пути к папке без двойных кавычек и без обратной косой черты. Обратная косая черта в конце не будет проблемой, но двойные кавычки в пути к папке могут быть проблематичными из-за того, что значение PathToFolder объединяется с другими строками во время выполнения пакетного файла.

Важны две строки:

del /A /F /Q "%PathToFolder%\*" >nul 2>nul
for /F "eol=| delims=" %%I in ('dir "%PathToFolder%\*" /AD /B 2^>nul') do rd /Q /S "%PathToFolder%\%%I" 2>nul

Команда DEL используется для удаления всех файлов в указанном каталоге.

• Опция /A необходима для обработки действительно всех файлов, включая файлы со скрытым атрибутом, которые DEL игнорирует без использования опции /A
• Опция /F необходима для принудительного удаления файлов с установленным атрибутом только для чтения.
• Опция /Q необходима для бесшумного удаления нескольких файлов без запроса пользователя, если необходимо удалить несколько файлов.
• >nul необходимо перенаправить вывод имен файлов, написанных для обработки STDOUT, на устройство NUL, которое невозможно удалить из-за того, что файл открыт или пользователь не имеет права удалять файл.
• 2>nul необходимо перенаправить вывод сообщения об ошибке для каждого файла, который не может быть удален из дескриптора STDERR на устройство NUL.

Команды FOR и RD используются для удаления всех подкаталогов в указанном каталоге. Но for/D не используется, потому что FOR игнорирует подкаталоги со скрытым набором атрибутов. По этой причине for/F используется для запуска следующей командной строки в отдельном командном процессе, запущенном в фоновом режиме с помощью cmd.exe/C:

dir "%PathToFolder%\*" /AD /B 2>nul

DIR в голом формате из-за /B записей в каталоге с атрибутом D, т.е. Имена всех подкаталогов в указанном каталоге не зависят от других атрибутов, таких как скрытый атрибут без пути. 2>nul используется для перенаправления вывода сообщения об ошибке с помощью DIR по ни одному каталогу, найденному из дескриптора STDERR, на устройство NUL.

Оператор перенаправления > должен быть экранирован с символом каретки ^ в командной строке FOR, чтобы интерпретироваться как буквенный символ, когда интерпретатор команд Windows обрабатывает эту командную строку перед выполнением команды FOR, которая выполняет встроенную командную строку dir в отдельном командном процессе, запущенном в фоновом режиме.

FOR обрабатывает захваченный вывод, записанный для обработки STDOUT запущенного командного процесса, который является именами подкаталогов без пути и никогда не заключен в двойные кавычки.

FOR с опцией /F игнорирует пустые строки, которые здесь не встречаются, поскольку DIR с опцией /B не выводит пустые строки.

FOR также игнорирует строки, начинающиеся с точки с запятой, которая является символом конца строки по умолчанию. Имя каталога может начинаться с точки с запятой. По этой причине eol=| используется для определения символа вертикальной строки в качестве символа конца строки, который не может иметь ни один каталог или файл в его имени.

FOR разделил бы строку на подстроки, используя пробел и горизонтальную вкладку в качестве разделителей, и назначил бы только строку с ограниченным пространством/табуляцией для указанной переменной цикла I Это поведение расщепления здесь не требуется, поскольку имя каталога может содержать одно или несколько пробелов. Поэтому delims= используется для определения пустого списка разделителей, чтобы отключить поведение разделения строк и получить назначенную переменную цикла. I всегда являюсь полным именем каталога.

Команда FOR запускает команду RD для каждого имени каталога без пути, из-за чего в командной строке RD путь папки должен быть указан еще раз, который объединяется с именем подпапки.

Чтобы понять используемые команды и как они работают, откройте окно командной строки, выполните там следующие команды и тщательно прочитайте все страницы справки, отображаемые для каждой команды.

• del/?
• dir/?
• echo/?
• endlocal/?
• for/?
• goto/?
• if/?
• rd/?
• rem/?
• set/?
• setlocal/?

Чтобы удалить файл:

del PATH_TO_FILE

Чтобы удалить папку со всеми файлами в ней:

rmdir /s /q PATH_TO_FOLDER

Удаление всех файлов из определенной папки (не удаление самой папки) немного сложнее. del /s *.* не удается удалить папки, но удаляет файлы из всех подпапок. Поэтому необходимы две команды:

del /q PATH_TO_FOLDER\*.*
for /d %i in (PATH_TO_FOLDER\*.*) do @rmdir /s /q "%i"

Я попробовал несколько из этих подходов, но никто не работал должным образом.
Я нашел этот двухэтапный подход на сайте Windows Command Line:

forfiles /P %pathtofolder% /M * /C "cmd /c if @isdir==FALSE del @file"

forfiles /P %pathtofolder%  /M * /C "cmd /c if @isdir==TRUE rmdir /S /Q @file"

Он работал точно так, как мне было нужно, и, как указано ОП.

@ECHO OFF
rem next line removes all files in temp folder
DEL /A /F /Q /S "%temp%\*.*"
rem next line cleans up the folder content
FOR /D %%p IN ("%temp%\*.*") DO RD "%%p" /S /Q

del %pathtofolder%\*.*   /s /f  /q

удалить все файлы и подпапки в% pathtofolder%, включая файлы только для чтения, не запрашивать подтверждение